Запретить SAS автоматически удалять конечные пробелы в строке

Я не совсем понял, что вы пытаетесь сделать с ksubstr, но если вы хотите добавить отступы, чтобы получить общую длину до 20 символов, вам, возможно, придется написать дополнительную логику:

data _null_ ;
 set d01 ;
 file "/folders/myfolders/test.csv" lrecl=1000 ;
 length filler $20;
 w_out = ksubstr(Name,1,5) || IdNumber || Salary || Site;

 len = 20 - klength(w_out) - 1;
 put w_out @;
 if len > 0 then do;
   filler = repeat(" ", len);
   put filler $varying20. len;
 end;
 else put;
run ;

Вы, вероятно, не хотите писать фиксированный файл столбца, используя многобайтовый набор символов. Вместо этого посмотрите, можете ли вы настроить свой процесс для использования файла с разделителями. Как и в вашем примере ввода данных.

Если вы хотите, чтобы функция PUT записывала определенное количество байтов, просто используйте форматированный оператор PUT. Чтобы количество записываемых байтов менялось в зависимости от значения строки, вы можете использовать формат $VARYING. Синтаксис при использовании $VARYING немного отличается от обычного формата. Вы добавляете вторую ссылку на переменную после спецификации формата, которая содержит фактическое количество байтов для записи.

Вы можете использовать функцию LENGTH(), чтобы вычислить, сколько байтов занимают ваши значения имени. Поскольку он обычно игнорирует завершающий пробел, просто добавьте еще один символ в конец и вычтите один из общей длины.

Чтобы заполнить конец тремя пробелами, вы можете просто добавить три к ширине, используемой в формате для последней переменной.

data d01;
  infile datalines dlm='#';
  length Name $15 IdNumber $4 Salary $5 Site $3 ;
  input Name -- Site;
datalines;
ｱｲ# 2355# 21163# BR1
ｱｲｳｴｵ# 5889# 20976# BR1
ｶｷｸｹ# 3878# 19571# BR2
Sam#1#2#3
;

filename out temp;
data _null_;
  set d01;
  file out;
  nbytes=length(ksubstr(name,1,5)||'#')-1;
  put name $varying15. nbytes IdNumber $4. Salary $5. Site $6. ;
run;

Полученные результаты:

67    data _null_ ;
68      infile out;
69      input ;
70      list;
71    run;

NOTE: The infile OUT is:
      Filename=...\#LN00059,
      RECFM=V,LRECL=32767,File Size (bytes)=110,
      Last Modified=15Aug2019:09:01:44,
      Create Time=15Aug2019:09:01:44

RULE:     ----+----1----+----2----+----3----+----4----+----5----+----6----+----7----+----8----+----9----+----0
1         ｱｲ   235521163BR1    24
2         ｱｲｳｴｵ588920976BR1    30
3         ｶｷｸｹ 387819571BR2    28
4         Sam  1   2    3      20
NOTE: 4 records were read from the infile OUT.
      The minimum record length was 20.
      The maximum record length was 30.

По умолчанию SAS устанавливает параметр NOPAD в операторе FILE, он также устанавливает для каждой строки «переменный формат», что означает, что длина строк может варьироваться в зависимости от записываемых данных. Чтобы явно попросить SAS заполнить ваши записи пробелами, не используйте переменную-заполнитель, просто:

• Установите LRECL на ширину файла, который вам нужен (20)
• Установите параметр PAD или установите RECFM=F

Образец кода:

data _null_ ;
 set d01 ;
 file "/folders/myfolders/test.csv" lrecl=20 PAD;
 w_out = Name || IdNumber || Salary || Site;
 put w_out;
run ;

Подробнее здесь: http://support.sas.com/documentation/cdl/en/lrdict/64316/HTML/default/viewer.htm#a000171874.htm#a000220987