Несколько зон доступности с терраформом на AWS

Можно равномерно распределить экземпляры по нескольким зонам, используя модуль по модулю.

variable "zone" {
  description = "for single zone deployment"
  default = "europe-west4-b"
}

variable "zones" {
  description = "for multi zone deployment"
  default = ["europe-west4-b", "europe-west4-c"]
}

resource "google_compute_instance" "default" {
  count = "${var.role.count}"
  ...
  zone = "${var.zone != "" ? var.zone: var.zones[ count.index % length(var.zones) ]}"
  ...
}

Этот механизм распределения позволяет равномерно распределять узлы по зонам.
Например, Zone = [A, B] - экземпляр-1 будет в A, экземпляр-2 будет в B, экземпляр-3 снова будет в A.
При добавлении зоны C к зонам экземпляр-3 будет перемещен в C.

В конце концов, я понял, как это сделать, используя data "aws_subnet_ids" {...} и, что более важно, понял, что terraform создает списки из ресурсов при использовании count:

variable "target_vpc" {}
variable "app_server_count" {}
variable "app_server_ip_start" {}

# Discover VPC
data "aws_vpc" "target_vpc" {
  filter = {
    name = "tag:Name"
    values = ["${var.target_vpc}"]
  }
}

# Discover subnet IDs. This requires the subnetworks to be tagged with Tier = "AppTier"
data "aws_subnet_ids" "app_tier_ids" {
  vpc_id = "${data.aws_vpc.target_vpc.id}"
  tags {
    Tier = "AppTier"
  }
}

# Discover subnets and create a list, one for each found ID
data "aws_subnet" "app_tier" {
  count = "${length(data.aws_subnet_ids.app_tier_ids.ids)}"
  id = "${data.aws_subnet_ids.app_tier_ids.ids[count.index]}"
}

resource "aws_instance" "app_server" {
  ...

  # Create N instances
  count = "${var.app_server_count}"

  # Use the "count.index" subnet
  subnet_id = "${data.aws_subnet_ids.app_tier_ids.ids[count.index]}"

  # Create an IP address using the CIDR of the subnet
  private_ip = "${cidrhost(element(data.aws_subnet.app_tier.*.cidr_block, count.index), var.app_server_ip_start + count.index)}"

  ...
}

Индекс счетчика в ресурсе вызовет ошибку, если у вас больше экземпляров, чем подсетей. Используйте интерполяцию элементов из Terraform

element (list, index) - возвращает единственный элемент из списка по заданному индексу. Если индекс больше, чем количество элементов, эта функция будет завершена с использованием стандартного алгоритма модификации. Эта функция работает только с плоскими списками.

subnet_id = "${element(data.aws_subnet_ids.app_tier_ids.ids, count.index)}"

Я получаю Terraform для обхода подсетей в зоне доступности с помощью aws_subnet_ids источник данных и фильтрация по тегу, представляющему уровень (в моем случае общедоступный / частный).

Тогда это выглядит примерно так:

variable "vpc" {}
variable "ami" {}
variable "subnet_tier" {}
variable "instance_count" {}

data "aws_vpc" "selected" {
  tags {
    Name = "${var.vpc}"
  }
}

data "aws_subnet_ids" "selected" {
  vpc_id = "${data.aws_vpc.selected.id}"

  tags {
    Tier = "${var.subnet_tier}"
  }
}

resource "aws_instance" "instance" {
  count         = "${var.instance_count}"
  ami           = "${var.ami}"
  subnet_id     = "${data.aws_subnet_ids.selected.ids[count.index]}"
  instance_type = "${var.instance_type}"
}

Это возвращает согласованный порядок сортировки, но не обязательно начиная с AZ A в вашем аккаунте. Я подозреваю, что API AWS возвращает подсети в порядке AZ, но упорядочивает их по собственному внутреннему идентификатору, поскольку AZ перетасовываются по учетной записи (предположительно, чтобы остановить затопление AZ A, поскольку люди предсказуемо плохо помещают все в первую очередь, что они могут использовать) .

Вам придется связать себя ужасными узлами, если по какой-то странной причине вы особенно заботитесь о том, чтобы инстансы были размещены в первую очередь в AZ A, но этот минимальный пример должен, по крайней мере, получить экземпляры, проходящие циклический перебор через AZ, в которых у вас есть подсети, полагаясь на Terraform's обратный цикл по массивам при превышении длины массива.

Для всех, кто предлагает count.index в подходе aws_instance, это не лучший вариант, потому что он не работает, если у вас больше экземпляров, чем подсетей.