Есть ли способ изменить вывод командной строки перед сохранением в файл?

Возможно, поможет следующее, я считаю, что вы можете использовать его и настроить для собственного использования: Пакетная обработка — анализ вывода Tracert

Точная формула для пропуска N первых строк из вывода одной команды:

for /f "skip=N tokens=*" %a in ('<command>') do @echo %a

В твоем случае:

for /f "skip=4 tokens=*" %a in ('tracert -h 30 -w 500 XX.XXX.XXX.XX ') do @echo %a >> cmd_output.txt

Используя ваши ответы и еще несколько поисков, я придумал это решение:

@echo off
rem token 1 is hop-number
rem token 6,7 or 8 may be IP, depending on whether 2 or less requests dont receive a response.
for /f "tokens=1,6,7,8 delims=* " %%a in ('tracert -d -h 30 -w 350 8.8.8.8^|findstr /bc:" " ') do (
  echo %%a, %%b, %%c, %%d
  )>>ips.txt
endlocal

Это дает следующий ответ:

1, <1, ms, 192.168.1.240
2, 1, ms, 195.114.237.65
3, 1, ms, 94.247.72.33
4, <1, ms, 82.150.154.129
5, 1, ms, 217.170.0.244
6, 2, ms, 193.239.117.142
7, 2, ms, 108.170.241.140
8, 2, ms, 216.239.41.49
9, 5, ms, 74.125.37.130
10, 209.85.243.253, , 
11, 5, ms, 108.170.237.135
12, , , 
13, 5, ms, 8.8.8.8

В каждой строке перед первой запятой всегда указывается номер перехода. Тогда IP-адрес может быть после первой, второй или третьей запятой. Поскольку tracert отправляет три запроса на переход, один, два или три из этих запросов могут завершиться ошибкой.

Если запрос завершается неудачно, результатом будет «*» вместо «X мс», и, поскольку я разделяю пробелами, если бы я всегда брал 8-й токен, он мог бы не содержать IP-адрес или что-либо в этом отношении.

Этот код всегда будет содержать IP-адрес, но по-прежнему будет содержать некоторые лишние данные, если число неудачных запросов меньше двух, потому что тогда токен 6 или 7 будет содержать некоторую часть «X мс».

В ответе вы увидите, что все запросы были успешными, за исключением прыжка 10, где два запроса завершились неудачно, и прыжка 12, где три запроса завершились неудачно, и поэтому tracert не смог вернуть IP-адрес.

Если у кого-нибудь есть какие-нибудь яркие идеи о том, как удалить эти последние биты лишних данных, мы будем признательны. В противном случае это вполне рабочий выход для меня. Так что спасибо за вашу помощь! :)

@echo off
setlocal enabledelayedexpansion
for /f "tokens=1,*" %%a in ('tracert -d -h 30 -w 350 8.8.8.8 ^|findstr /bc:" "') do (
  for %%c in (%%b) do set ip=%%c
  set ip=!ip:[=!
  set ip=!ip:]=!
  echo !ip!|findstr "[0-9]" >nul || set "ip=-"
  echo %%a, !ip!
)

второй for (%%c) получает самое последнее слово строки (которое является либо IP-адресом, либо IP-адресом в скобках, либо последним словом «Время ожидания запроса истекло» (out. в англоязычных версиях Windows). Остальная часть строк просто для украшения результата (удаление скобок, замена всего, что не имеет номера (не IP-адреса) на -

Возможно, вы захотите заменить две строки echo ... только на:

  echo !ip!|findstr "[0-9]" >nul && echo %%a, !ip!

Это не будет выводить строки без IP-адреса.

Подробнее о && и || см. SS64.

Для синтаксиса !variable! см. отложенное расширение