Использование to-отчетов при создании агентов из CSV-файла

В ответ на ваш комментарий - понял, подумал, что может быть так. Я представлю альтернативный подход, который может вам подойти или не подойти, но, вероятно, я бы решил эту проблему. Основное отличие состоит в том, что я бы сохранил списки рейтингов экрана и батареи в переменной черепахи, чтобы вы могли легко получить к ним доступ постфактум без необходимости отслеживать счетчики. Учитывая эти объявления переменных:

extensions [ csv ]

globals [ screen-headings battery-headings]

turtles-own [ 
  turtle-screen-list 
  turtle-battery-list
  turtle-screen-eval
  turtle-bat-eval
  turtle-sum-eval
  turtle-row-number
]

Я бы разделил заголовки CSV-файла на глобальные переменные screen-headings и battery-headings.

Затем я перебирал следующие строки csv, как вы сделали ниже, и разделял строки аналогичным образом, но на turtles-own переменные turtle-screen-list и turtle-battery-list. Таким образом, каждая черепаха знает свои собственные рейтинги для каждого экрана и батареи, поэтому вы можете изменить оцениваемый экран или батарею по мере необходимости.

Установите интересующий экран и батарею с помощью screen-to-evaluate и battery-to-evaluate (или используйте Chooser в интерфейсе), затем используйте генератор отчетов (аналогичный тому, что вы настроили), который проверяет положение интересующей батареи и экрана, чтобы вернуть текущую черепаху. рейтинг для каждого - это установит turtle-screen-eval и turtle-bat-eval. Наконец, суммируйте эти два последних значения.

to setup
  ca
  reset-ticks
  file-close-all
  file-open "turtle_details.csv"
  let headings csv:from-row file-read-line
  set screen-headings sublist headings 0 4
  set battery-headings sublist headings 4 length headings

  let screen-to-evaluate 13.5
  let battery-to-evaluate 24

  while [ not file-at-end? ] [
    let data csv:from-row file-read-line
    create-turtles 1 [
      set turtle-screen-list sublist data 0 4
      set turtle-battery-list sublist data 4 length data
      set turtle-screen-eval turtle-screen-rating screen-to-evaluate
      set turtle-bat-eval turtle-battery-rating battery-to-evaluate
      set turtle-sum-eval turtle-screen-eval + turtle-bat-eval
    ]
  ]
  file-close-all

end

to-report turtle-screen-rating [sc]
  let pos position sc screen-headings
  let turt-screen-rate-value item pos turtle-screen-list
  report turt-screen-rate-value
end

to-report turtle-battery-rating [bc]
  let pos position bc battery-headings
  let turt-bat-rate-value item pos turtle-battery-list
  report turt-bat-rate-value
end

Конечно, вы можете уплотнить некоторые из них по мере необходимости. Я протестировал эту настройку с 4 строками (по образцу данных вашего примера), и, похоже, она работает нормально. Если у вас огромное количество строк, это может не сработать.

Изменить:

Если вы в конечном итоге замените screen-to-evaluate и battery-to-evaluate средствами выбора интерфейса (что я рекомендую — это позволяет вам быстро увидеть различные значения), вы можете обновить до новых значений с помощью чего-то вроде:

to update-vals
  ask turtles [
    set turtle-screen-eval turtle-screen-rating scrn
    set turtle-bat-eval turtle-battery-rating batr
    set turtle-sum-eval turtle-screen-eval + turtle-bat-eval
  ]
end

где scrn и batr — имена выбирающих.

Или, если вы хотите, чтобы они динамически обновлялись, вы можете сделать монитор интерфейса, который сообщает следующий репортер:

to-report update
ask turtles [
    set turtle-screen-eval turtle-screen-rating scrn
    set turtle-bat-eval turtle-battery-rating batr
    set turtle-sum-eval turtle-screen-eval + turtle-bat-eval
  ]
  report "Dynamically updating."
end

В этом случае, как только вы измените значение Chooser, черепахи должны немедленно обновить свои turtle-bat-eval, turtle-screen-eval и turtle-sum-eval. Весело!

Изменить 2

Если ваш csv включает столбец для номеров строк, например:

row 12 13.5 14 15  5 12 24 30
1   1  2.0  1  3  2  2  4  5
2   4  3.0  1  2  1  1  2  3

Я бы рекомендовал создать переменную черепахи для хранения используемого номера строки. Теперь я включил один под названием turtle-row-number. Затем вам просто нужно будет включить строку для обновления этой переменной из элемента first в списке, который является номером строки, а затем соответствующим образом изменить ваши значения sublist на что-то вроде:

to setup-row-nums
  ca
  reset-ticks
  file-close-all
  file-open "turtle_details_2.csv"
  let headings csv:from-row file-read-line
  set screen-headings sublist headings 1 5
  set battery-headings sublist headings 5 length headings

  while [ not file-at-end? ] [
    let data csv:from-row file-read-line
    create-turtles 1 [
      set turtle-row-number first data 
      set turtle-screen-list sublist data 1 5
      set turtle-battery-list sublist data 5 length data
    ]
  ]
  update-vals
  file-close-all

end

Где update-vals как показано выше.