советы по созданию графических диаграмм

Немного обобщая ответ Самсдрама, я получаю

GraphPlotHighlight[edges:{((_->_)|{_->_,_})..},hl:{___}:{},opts:OptionsPattern[]]:=Module[{verts,coords,g,sub},
  verts=Flatten[edges/.Rule->List]//.{a___,b_,c___,b_,d___}:>{a,b,c,d};
  g=GraphPlot[edges,FilterRules[{opts}, Options[GraphPlot]]];
  coords=VertexCoordinateRules/.Cases[g,HoldPattern[VertexCoordinateRules->_],2];
  sub=Flatten[Position[verts,_?(MemberQ[hl,#]&)]];
  coords=coords[[sub]];     
  Show[Graphics[{OptionValue[HighlightColor],CapForm["Round"],JoinForm["Round"],Thickness[OptionValue[HighlightThickness]],Line[AppendTo[coords,First[coords]]],Polygon[coords]}],g]
]
Protect[HighlightColor,HighlightThickness];
Options[GraphPlotHighlight]=Join[Options[GraphPlot],{HighlightColor->LightBlue,HighlightThickness->.15}];

Часть приведенного выше кода можно было бы сделать немного более надежным, но он работает:

GraphPlotHighlight[{b->c,a->b,c->a,e->c},{b,c,e},VertexLabeling->True,HighlightColor->LightRed,HighlightThickness->.1,VertexRenderingFunction -> ({White, EdgeForm[Black], Disk[#, .06], 
Black, Text[#2, #1]} &)]

РЕДАКТИРОВАТЬ № 1: очищенную версию этого кода можно найти по адресу http://gist.github.com/663438

РЕДАКТИРОВАТЬ № 2. Как обсуждалось в комментариях ниже, шаблон, которому должен соответствовать мой edges, представляет собой список пограничных правил с необязательными метками. Это немного менее общее, чем то, что используется функцией GraphPlot (и версией, приведенной выше gist). ), где пограничные правила также разрешено заключать в Tooltip.

Чтобы найти точный шаблон, используемый GraphPlot, я неоднократно использовал Unprotect[fn];ClearAttributes[fn,ReadProtected];Information[fn], где fn — это интересующий объект, пока не обнаружил, что он использует следующую (очищенную) функцию:

Network`GraphPlot`RuleListGraphQ[x_] := 
  ListQ[x] && Length[x] > 0 && 
    And@@Map[Head[#1] === Rule 
         || (ListQ[#1] && Length[#1] == 2 && Head[#1[[1]]] === Rule) 
         || (Head[#1] === Tooltip && Length[#1] == 2 && Head[#1[[1]]] === Rule)&, 
      x, {1}]

Я думаю, что мой шаблон edges:{((_ -> _) | (List|Tooltip)[_ -> _, _])..} эквивалентен и более лаконичен...

Для простых примеров, когда вы соединяете только два узла (например, ваш пример справа), вы можете рисовать линии с закрытыми конечными точками, как это.

vertices = {a, b};
Coordinates = {{0, 0}, {1, 1}};
GraphPlot[{a -> b}, VertexLabeling -> True, 
 VertexCoordinateRules -> 
  MapThread[#1 -> #2 &, {vertices, Coordinates}], 
 Prolog -> {Blue, CapForm["Round"], Thickness[.1], Line[Coordinates]}]

Для более сложных примеров (например, второй справа) я бы рекомендовал нарисовать многоугольник, используя координаты вершин, а затем обвести край многоугольника линией с заглушками. Я не смог найти способ добавить скошенный край непосредственно к многоугольнику. При трассировке периметра многоугольника вам необходимо добавить координату первой вершины к концу отрезка линии, чтобы линия составляла полный периметр многоугольника. Кроме того, существуют две отдельные графические директивы для линий: CapForm, определяющая, скошены ли концы линии, и JoinForm, определяющая, скошены ли промежуточные точки линии.

vertices = {a, b, c};
Coordinates = {{0, 0}, {1, 1}, {1, -1}};
GraphPlot[{a -> b, b -> c, c -> a}, VertexLabeling -> True, 
 VertexCoordinateRules -> 
  MapThread[#1 -> #2 &, {vertices, Coordinates}], 
 Prolog -> {Blue, CapForm["Round"], JoinForm["Round"], Thickness[.15],
    Line[AppendTo[Coordinates, First[Coordinates]]], 
   Polygon[Coordinates]}]

JoinForm["Round"] будет округлять соединения сегментов линий.

Вам понадобится закрашенный многоугольник вокруг центров вершин в цветной области, а затем JoinForm["Round"], ..., Line[{...}], чтобы получить закругленные углы.

Consider

foo = GraphPlot[{a -> b, a -> c, b -> d, b -> e, b -> f, c -> e, e -> f}, 
    VertexRenderingFunction -> 
    ({White, EdgeForm[Black], Disk[#, .1], Black, Text[#2, #1]} &)]
Show[
    Graphics[{
      RGBColor[0.6, 0.8, 1, 1],
      Polygon[foo[[1, 1, 1, 1, 1, {2, 5, 6, 2}]]],
      JoinForm["Round"], Thickness[0.2],
      Line[foo[[1, 1, 1, 1, 1, {2, 5, 6, 2}]]]
    }],
    foo
]

где foo[[1,1,1,1,1]] — список центров вершин, а {2,5,6} извлекает вершины {b,e,f}. ({2,5,6,2} закрывает линию в исходной точке.)

Есть много места для украшения, но я думаю, что это покрывает ингредиент, который вы не упомянули выше.