Невозможно выбрать элемент в результате node-set() по имени, но * находит его

У меня есть таблица стилей XSLT 1.0*, которая выполняет некоторую предварительную обработку и создает фрагмент результата, состоящий из списка элементов <x>, каждый из которых имеет двух дочерних элементов — давайте тогда назовем <a> и <b>.

Итак, сгенерированный список выглядит так:

<x><a>A-content</a><b>B-content</b></x>
<x><a>A-content</a><b>B-content</b></x>
...
<x><a>A-content</a><b>B-content</b></x>

Затем я преобразовываю это в набор узлов с помощью node-set() и использую шаблоны применения для преобразования всех элементов <x> в выходное представление.

Все идет нормально.

Но я должен использовать правило match="*" в выходном шаблоне, и хотя я могу получить дочерние элементы, используя "*[1]" и "*[2]", я не могу найти их, используя "a" и "b" - я просто получаю пустой результат.

Позиционный синтаксис работает как обходной путь, но он довольно ненадежен, и я хотел бы вернуться к работе с именами элементов. Кроме того, это не очень читабельно.

Я подозревал, что это может быть проблема с пространством имен (<x>, <a> и <b> не определены в исходной схеме для входных или выходных документов), но, насколько я вижу, при выборе элементов с помощью " *".

На всякий случай, если это важно, я использую xsltproc под cygwin (libxml 20902, libxslt 10128 и libexslt 817).

Любые идеи о том, что я могу делать неправильно, или советы по отладке?

(*- Мне приходится использовать XSLT 1.0, поскольку он предназначен для работы в веб-браузере.)

РЕДАКТИРОВАТЬ: добавлены примеры по запросу

Введите test.xml:

<?xml version="1.0" encoding="utf-8"?>
<?xml-stylesheet href="test.xsl" type="text/xsl" ?>

<books>
    <book>
        <title>Diaspora</title>
        <author>Greg Egan</author>
    </book>

    <book>
        <title>2001</title>
        <author>Arthur C Clarke</author>
    </book>

    <book>
        <title>Eon</title>
        <author>Greg Bear</author>
    </book>
</books>

Преобразование test.xslt:

<?xml version="1.0" encoding="utf-8"?>

<xsl:stylesheet version="1.0"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns="http://www.w3.org/1999/xhtml"
                                xmlns:exslt="http://exslt.org/common"
                                xmlns:xalan="http://xml.apache.org/xalan"
                                xmlns:msxslt="urn:schemas-microsoft-com:xslt"
                                exclude-result-prefixes="xsl msxslt exslt xalan">
<!--    extension-element-prefixes="exslt"> -->

    <xsl:template match="books">
        <!-- Generate list -->
        <xsl:variable name="list">
            <xsl:apply-templates select="book" mode="phase1"/>
        </xsl:variable>

        <html>
            <head>
                <title>Books</title>
            </head>
            <body>
                <xsl:choose>
                    <xsl:when test="function-available('msxslt:node-set')">
                        <xsl:apply-templates select="msxslt:node-set($list)" mode="process-list"/>
                    </xsl:when>
                    <xsl:when test="function-available('exslt:node-set')">
                        <xsl:apply-templates select="exslt:node-set($list)" mode="process-list"/>
                    </xsl:when>
                    <xsl:when test="function-available('xalan:nodeset')">
                        <xsl:apply-templates select="xalan:nodeset($list)"  mode="process-list"/>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:apply-templates select="$list" mode="process-list"/>
                    </xsl:otherwise>
                </xsl:choose>
            </body>
        </html>
    </xsl:template>

    <xsl:template match="book" mode="phase1">
        <!-- Actual transformation is more involved -->
        <xsl:element name="x">
            <xsl:element name="a">
                <b>
                    <xsl:value-of select="author/text()"/>
                </b>
            </xsl:element>
            <xsl:element name="b">
                <i>
                    <xsl:value-of select="title/text()"/>
                </i>
            </xsl:element>
        </xsl:element>
    </xsl:template>

    <xsl:template match="*" mode="process-list">
        <p>
            [<xsl:value-of select="*[1]"/>]
            [<xsl:value-of select="*[2]"/>]
            [<xsl:value-of select="a"/>]
            [<xsl:value-of select="b"/>]
        </p>
    </xsl:template>

</xsl:stylesheet>

Выходные данные (одинаковые выходные данные как для msxslt, так и для xsltproc):

<?xml version="1.0" encoding="utf-8"?>
<html xmlns="http://www.w3.org/1999/xhtml">
    <head><title>Books</title></head>
    <body>
        <p>
            [Greg Egan]
            [Diaspora]
            []
            []
        </p><p>
            [Arthur C Clarke]
            [2001]
            []
            []
        </p><p>
            [Greg Bear]
            [Eon]
            []
            []
        </p>
    </body>
</html>

xml xml-namespaces xslt xslt-1.0 node-set
person Sean Ellis    schedule 12.02.2016    source источник
comment
Покажите воспроизводимый пример.   -  person michael.hor257k    schedule 12.02.2016
comment
@MathiasMüller Почему вы решили, что это не проблема пространства имен?   -  person michael.hor257k    schedule 12.02.2016
comment
@ michael.hor257k Я не решил, что это не проблема пространства имен (очевидно, это является проблемой пространства имен), но, по моему мнению, лучше выделить информацию о том, что решение должно быть XSLT 1.0. важнее, чем тег пространств имен. Очень немногие вопросы, в которых проблема заключается в пространствах имен, помечены xml-namespaces. Не стесняйтесь отменить это изменение, если вы не согласны.   -  person Mathias Müller    schedule 12.02.2016
comment
@MathiasMüller А, я не знал, что существует ограничение в 5 тегов.   -  person michael.hor257k    schedule 12.02.2016
comment
Re: пространства имен. Если я удалю элемент exclude-result-prefixes и использую copy-of вместо value-of, то вывод будет выглядеть как [‹a›‹b›Greg Bear‹/b›‹/a›] [‹b›‹i ›Эон‹/i›‹/b›] [] []   -  person Sean Ellis    schedule 12.02.2016
comment
... поэтому, насколько я вижу, никаких признаков того, что элементам <a> и <b> назначаются дополнительные пространства имен, нет. Если я запускаю это в отладчике XSLT в Visual Studio, я также не вижу мошеннических пространств имен. И все же названное совпадение... не соответствует.   -  person Sean Ellis    schedule 12.02.2016
comment
Если я явно добавлю пространство имен, используя <xsl:element name="a" namespace="ln">, то оно появится в выводе как <a xmlns="ln"><b xmlns="http://www.w3.org/1999/xhtml">Greg Bear</b></a>, чего я и ожидал, но совпадение с явным использованием пространства имен — "ln:a" — по-прежнему ничего не возвращает.   -  person Sean Ellis    schedule 12.02.2016

Ответы (2)


arrow_upward
0
arrow_downward

Я продолжил поиски и нашел решение. Как мы и подозревали, это была проблема с пространством имен — вот предыдущий пост с описанием этого.

Несмотря на мои попытки поместить новые элементы в новое пространство имен, они по-прежнему попадали в пространство имен по умолчанию, которое я объявил как:

xmlns="http://www.w3.org/1999/xhtml"

Однако это не рассматривается как значение по умолчанию в выражении XPATH, поэтому оно не было найдено. (Второстепенный вопрос - почему бы и нет?)

Решение состояло в том, чтобы повторить объявление пространства имен по умолчанию с префиксом пространства имен:

xmlns:xhtml="http://www.w3.org/1999/xhtml"

и используйте этот префикс явно в xpath:

[<xsl:copy-of select="xhtml:a"/>]
[<xsl:copy-of select="xhtml:b"/>]

Тогда все совпадает, и я получаю идентичный вывод из именованного и позиционного выражений XPATH.

Спасибо всем за то, что они выступили в роли резонатора - надеюсь, это поможет кому-то еще позже.

person Sean Ellis    schedule 12.02.2016
comment
Другой вариант — явно поместить созданные элементы в пространство без имен, например. <x xmlns=""> или <xsl:element name="x" namespace="''">. -- Однако это не рассматривается как значение по умолчанию в выражении XPATH Для этого вам потребуется XSLT 2.0: w3.org/TR/xslt20/#элемент таблицы стилей - person michael.hor257k; 12.02.2016

arrow_upward
-1
arrow_downward

Я могу только предположить, что вы используете расширение exslt для создания набора узлов, и я предполагаю, что вы пытаетесь настроить многопроходное преобразование:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:exsl="http://exslt.org/common"
                extension-element-prefixes="exsl">

<xsl:template match="/">
  <!-- create your first pass here -->
  <xsl:variable name="first-pass">
      <xsl:apply-templates mode="first-pass"/>
  </xsl:variable>
  <xsl:apply-templates select="exsl:node-set($first-pass)" mode="second-pass"/>
</xsl:template>

<!-- implementation of first-pass
    ....
 -->

<!-- second-pass: find a and b elements in x -->
<xsl:template match="x/a" mode="second-pass">
    <!-- your turn -->
</xsl:template>

<xsl:template match="x/b" mode="second-pass">
    <!-- your turn -->
</xsl:template>

<xsl:template match="@*|node()" mode="second-pass">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()" mode="second-pass"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="@*|node()" mode="first-pass">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()" mode="first-pass"/>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>
person GomX    schedule 12.02.2016
comment
Да, это то, что я делаю. Моя проблема в том, что если я использую эту конструкцию для второго прохода, шаблоны, соответствующие x/a и x/b, никогда не срабатывают (и не только x). Вместо этого у меня есть шаблон, который соответствует * для второго прохода, который выбирает все элементы <x>, потому что это все, что есть в списке на верхнем уровне. При этом <xsl:copy-of select="*[1]"/> будет копировать элемент <a>, а <xsl:copy-of select="a"/> ничего не копирует. - person Sean Ellis; 12.02.2016