Почему CharInSet быстрее, чем оператор Case?

AQTime - инструментальный профилировщик. Инструментальные профилировщики часто не подходят для измерения времени кода, особенно в таких микробенчмарках, как ваш, потому что стоимость инструментария часто превышает стоимость измеряемого объекта. С другой стороны, инструменты профилировщика лучше всего подходят для профилирования памяти и других ресурсов.

Профилировщики выборки, которые периодически проверяют расположение ЦП, обычно лучше подходят для измерения времени кода.

В любом случае, вот еще один микробенчмарк, который действительно показывает, что оператор case быстрее, чем CharInSet. Однако обратите внимание, что проверка набора все еще может использоваться с приведением типа для устранения предупреждения об усечении (фактически это единственная причина, по которой существует CharInSet):

{$apptype console}

uses Windows, SysUtils;

const
  SampleString = 'foo bar baz blah de;blah de blah.';

procedure P1;
var
  cp: PChar;
begin
  cp := PChar(SampleString);
  while not CharInSet(cp^, [#0, ';', '.']) do
    Inc(cp);
end;

procedure P2;
var
  cp: PChar;
begin
  cp := PChar(SampleString);
  while True do
    case cp^ of
      '.', #0, ';':
        Break;
    else
      Inc(cp);
    end;
end;

procedure P3;
var
  cp: PChar;
begin
  cp := PChar(SampleString);
  while not (AnsiChar(cp^) in [#0, ';', '.']) do
    Inc(cp);
end;

procedure Time(const Title: string; Proc: TProc);
var
  i: Integer;
  start, finish, freq: Int64;
begin
  QueryPerformanceCounter(start);
  for i := 1 to 1000000 do
    Proc;
  QueryPerformanceCounter(finish);
  QueryPerformanceFrequency(freq);
  Writeln(Format('%20s: %.3f seconds', [Title, (finish - start) / freq]));
end;

begin
  Time('CharInSet', P1);
  Time('case stmt', P2);
  Time('set test', P3);
end.

Его вывод на моем ноутбуке:

CharInSet: 0.261 seconds
case stmt: 0.077 seconds
 set test: 0.060 seconds

Барри, я хотел бы отметить, что ваш тест не отражает фактическую производительность различных методов, потому что структура реализаций различается. Вместо этого все методы должны использовать конструкцию while True do, чтобы лучше отразить влияние различных способов выполнения проверки char-in-set.

Вот замена тестовым методам (P2 без изменений, P1 и P3 теперь используют конструкцию while True do):

procedure P1;
var
  cp: PChar;
begin
  cp := PChar(SampleString);
  while True do
    if CharInSet(cp^, [#0, ';', '.']) then
      Break
    else
      Inc(cp);
end;

procedure P2;
var
  cp: PChar;
begin
  cp := PChar(SampleString);
  while True do
    case cp^ of
      '.', #0, ';':
        Break;
    else
      Inc(cp);
    end;
end;

procedure P3;
var
  cp: PChar;
begin
  cp := PChar(SampleString);
  while True do
    if AnsiChar(cp^) in [#0, ';', '.'] then
      Break
    else
      Inc(cp);
end;

Моя рабочая станция дает:

CharInSet: 0.099 seconds
case stmt: 0.043 seconds
 set test: 0.043 seconds

Что лучше соответствует ожидаемым результатам. Мне кажется, что использование конструкции case in не очень помогает. Прости, Марко!

Здесь можно найти бесплатный профилировщик выборки для Delphi:

https://forums.codegear.com/thread.jspa?messageID=18506

Помимо проблемы некорректного измерения времени инструментальными профилировщиками, следует отметить, что то, что будет быстрее, также будет зависеть от того, насколько предсказуемы ветви «case». Если тесты в «case» имеют одинаковую вероятность встретиться, производительность «case» может оказаться ниже, чем у CharInSet.

Код в функции CharInSet быстрее, чем case, время тратится на вызов, используйте while not (cp ^ in [..]), затем

вы увидите, что это пост.

Насколько я знаю, call требует того же количества операций процессора, что и jump, если они оба используют короткие указатели. С длинными указателями может быть иначе. Вызов на ассемблере по умолчанию не использует стек. Если имеется достаточно свободных регистров, используется регистр. Таким образом, операции со стеком также занимают нулевое время. Это просто регистры, что очень быстро.

В противоположном варианте, как я вижу, используются операции добавления и подгруппы, которые довольно медленны и, вероятно, добавляют большую часть дополнительного времени.