веб-сайт Проблема входа в систему Подтверждение запроса с использованием WinHTTPrequest.5.1 / Microsoft.XMLHTTP в VBA

Я не могу опубликовать «код», но могу опубликовать некоторую структуру. Если у вас возникли проблемы с этим, используйте Fiddler, чтобы проверить скрытую строку POST при успешном входе в систему и продублировать ее. .

Метод состоит в том, чтобы сначала ПОЛУЧИТЬ страницу и прочитать токен. Добавьте токен и любые другие случайные элементы формы ‹input› в строку отправки и отправьте сообщение POST.

Я сделал некоторые вары общедоступными, так как они могут использоваться в других процедурах. Убедитесь, что у вас нет двух объявлений Option Explicit в верхней части листа модуля.

Option Explicit

Public pUSR As String
Public pPWD As String
'you might need this elsewhere; make it a public string
Public pTOKENID As String
'you might need one of these too
Public pJSESSIONID As String
'you want to go here
Public Const csLOGINpg = "https://indexes.nasdaqomx.com/Account/LogOn"
Public Const csTOKENnm = "__RequestVerificationToken"

Sub mcr_XML_LogIn()
    Dim htmlBDY As New MSHTML.HTMLDocument, xmlHTTP As New MSXML2.ServerXMLHTTP60

    Dim iEL As Long, xmlSend As String

    On Error GoTo bm_Err_Report

    pJSESSIONID = vbNullString
    pTOKENID = vbNullString
    pUSR = "xxxxxx"
    pPWD = "xxxxxxx"

    With xmlHTTP
        .Open "GET", csLOGINpg, False
        .SetRequestHeader "Content-Type", "text/html;charset=UTF-8"
        .SetRequestHeader "Connection", "keep-alive"
        .send

        htmlBDY.body.innerHTML = .responseText

        If CBool(htmlBDY.getElementsByTagName("form").Length) Then
            With htmlBDY.getElementsByTagName("form")(0)
                For iEL = 0 To (.getElementsByTagName("input").Length - 1)
                    If htmlBDY.getElementsByTagName("input")(iEL).Name = csTOKENnm Then
                        pTOKENID = htmlBDY.getElementsByTagName("input")(iEL).Value
                        Exit For
                    End If
                Next iEL
            End With
        End If

        .Open "POST", csLOGINpg, False
        .SetRequestHeader "Content-type", "application/x-www-form-urlencoded"
        .SetRequestHeader "Connection", "keep-alive"
        'you may need to send a JSESSIONID cookie; Fiddler will tell you this and other stuff
        '.SetRequestHeader "Cookie", "JSESSIONID=" & pJSESSIONID
        xmlSend = csTOKENnm & Chr(61) & pTOKENID & "&RememberMe=false&UserName=" & pUSR & "&Password=" & pPWD
        Debug.Print xmlSend

        .send xmlSend
        htmlBDY.body.innerHTML = .responseText
    End With  'done with the xmlHTTP object for now

    'do something with what you received here (maybe check for a successful log-in)
    Debug.Print Left(htmlBDY.body.innerHTML, 1024)

    GoTo bm_Safe_Exit

bm_Err_Report:
    Debug.Print Err.Number & " - " & Err.Description

bm_Safe_Exit:
    Set htmlBDY = Nothing
    Set xmlHTTP = Nothing
End Sub

Да, это основано на объекте MSXML2.ServerXMLHTTP60, но это тот объект, который хранит IO и который можно легко отредактировать для публичного распространения.

Если вы используете этот код, не изменяя его на WinHTTP, вам потребуются справочные библиотеки Microsoft XML v6.0 и Microsoft Internet Controls, добавленные в Инструменты ► Справочники VBE.

Я просмотрел это, чтобы убедиться, что нахожусь на нужной странице. Строка xmlSend была,

 __RequestVerificationToken=RHr1FDomqqHEZQJPmMVqdwoFKVsK43uE3j1g+IWRF3nHqmxZGDyAxpUWqes2XCKgHVhHPnpLCcn3EOIKHJ30EoQbBOhV16IkS7oqPQm+3x5cex0GAWzfUYuzOGGYM35/Xa6jsXF7YsN78b3TzadIwS/8EENNdA6jSqtXgH7cDU/FNIRuMJQbO9dplwtglcg8&RememberMe=false&UserName=xxxxxx&Password=xxxxxxx

... так он получал токен. Первые 1024 символа .innerHTML были:

<HEADER id=headerContent class=spacer>
<DIV id=logoRow class=row-fluid>
<DIV class=container>
<DIV class=row-fluid>
<DIV class=span6><A class=noLinkExternal href="http://nasdaqomx.com/"><IMG id=Nasdaqlogo style="MARGIN-RIGHT: -3px" alt="Nasdaq logo" src="about:/Content/Images/nasdaq_logo.png"></A> <A href="about:/"><IMG id=logo alt="Nasdaq Global Indexes" src="about:/Content/Images/global_indexes.png"></A> </DIV>
<DIV class=span6>
<DIV class=floatRight>
<UL id=loginList class=hideListStyle>
<LI class=hidden-phone><A id=LoginLink class=noLinkExternal>Log In</A></LI>
<LI class=visible-phone><A href="about:/Account/LogOn">Log In</A></LI>
<LI><A href="about:/Home/IndexData">Register</A></LI></UL><INPUT id=siteSearch class=ui-autocomplete-input value=Search> </DIV></DIV></DIV></DIV></DIV>
<DIV id=menuContainer>
<DIV class=container>
<DIV class=row-fluid>
<DIV class=span12>
<DIV id=LoginPanel class=inputForm>
<FORM method=post action=/Account/LogOn><INPUT type=hidden value=EpSOScbAMNDv1lIjBnm8Xew4Rn

Надеюсь это поможет. Используйте Fiddler для решения любых проблем. Извините, но без действительных учетных данных я больше ничего не могу сделать.