Как вернуться к предыдущему моменту

Вот один из способов (это работающая демонстрация):

import Reactive.Banana
import Reactive.Banana.Frameworks
import Control.Monad
import Control.Applicative -- Needed if you aren't on GHC 7.10.

desc addDriver = do
    -- Refreshes the button state. Presumably fired by external IO.
    eButtonDriver <- fromAddHandler addDriver
    let -- Canonical repersentation of the button state.
        bButtonState = stepper False eButtonDriver
        -- Observes the button just before changing its state.
        ePreviousState = bButtonState <@ eButtonDriver
        -- Performs the test your f function would do.
        newlyPressed :: Bool -> Bool -> Bool
        newlyPressed previous current = not previous && current
        -- Applies the test. This works because eButtonDriver and
        -- ePreviousState are fired simultaneously.
        eNewlyPressed = unionWith newlyPressed
            ePreviousState eButtonDriver
        -- The same but more compactly, without needing ePreviousState.
        {-
        eNewlyPressed = newlyPressed <$> bButtonState <@> eButtonDriver
        -}
    reactimate (print <$> eNewlyPressed)

main = do
    (addDriver, fireDriver) <- newAddHandler
    network <- compile (desc addDriver)
    actuate network
    -- Demo: enter y to turn the button on, and any other string to
    -- turn it off.
    forever $ do
        buttonState <- (== "y") <$> getLine
        fireDriver buttonState

Примечания:

• События преходящи, действия постоянны — хорошее общее правило, позволяющее решить, что вам нужно: поведение или поток событий. В этом случае вам нужно посмотреть, в каком состоянии была кнопка до обновления, чтобы решить, была ли она недавно обновлена. В таком случае естественно представить состояние кнопки поведением (bButtonState), которое обновляется внешним событием (eButtonDriver).
• Для получения подробной информации о том, что делают комбинаторы, см. Reactive.Banana.Combinators.
• Мелкий шрифт о времени событий и обновлений поведения в реактивном банане см. в разделе этот вопрос.
• В зависимости от того, что вы пытаетесь сделать, changes может оказаться полезной. Помните о предостережениях, связанных с этим, упомянутых в документации.