Такие возможности ограничения регистра переключения не реализованы в specman. Однако разработчики предоставили нам макросы, с помощью которых мы можем реализовать многие творческие идеи, такие как эта.
Ограничение переключения регистра, которое вы запрашиваете, может быть легко реализовано с помощью конкатенации тернарных ограничений:
Keep a==1 ? exp1 : a==2 ? exp2 : exp3;
Конечно, макрос, создающий такие ограничения, должен уметь обрабатывать любое количество различных случаев. Рассмотрим этот макрос:
define <switch_case_gen'struct_member> "keep map <exp> \[<exp>,...\] to <exp> \[<exp>,...\]" as computed {
var num_s:string = str_expand_dots(<2>);
var str_s: string = str_expand_dots(<4>);
var ln:list of string = str_split(num_s,",");;
var ls:list of string = str_split(str_s,",");
if (ln.size() != ls.size()) {
error("keep map - you need to specify an equal number for items for both lists");
};
if (ln.size()<2) {
error("keep map - this macro should recieve lists of at least size 2");
};
var constraint:string;
constraint="keep ";
for each in ln {
if (index == ln.size()-1) {constraint = append(constraint,<3>,"==",ls[index],";");}
else {constraint = append(constraint,<1>,"==",ln[index]," ? ", <3>,"==",ls[index],":");};
};
out("parsed constraint is : ",constraint);
return constraint;
};
Пример использования в этом случае:
struct s {
id:uint(bits:2);
str:string;
keep map id [0,1,2,3] to str ["id0","id1","id2","id3"]
};
person
yuvalg
schedule
23.03.2015