Получить букву VBSCript USB-накопителя

Вот, который показывает список подключенных USB-накопителей.

On Error Resume Next
    strComputer = "."
    Dim oFSO, oDrive
    Set oFSO = WScript.CreateObject("Scripting.FileSystemObject")
    Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
    Set colItems = objWMIService.ExecQuery("SELECT * FROM Win32_DiskDrive WHERE InterfaceType = 'USB'")
    For Each objItem in colItems
      Wscript.Echo objItem.Caption
    Next

Мне нужно получить букву диска, но это невозможно с кодом выше. Буква диска для colItems не имеет свойства. Я могу использовать другой скрипт, который поддерживает букву диска, вот он:

Dim oFSO, oDrive
Const USBDRIVE=1
Set oFSO = WScript.CreateObject("Scripting.FileSystemObject")
For Each oDrive In oFSO.Drives
If oDrive.DriveType = USBDRIVE And oDrive.DriveLetter <> "A" Then
WScript.Echo oDrive.DriveLetter
End If
Next

Но в этом скрипте я не могу использовать свойство Caption, потому что оно не поддерживается :( Мне нужно объединить эти два скрипта, чтобы получить каждый заголовок и букву USB-накопителя. Как я могу это сделать? Возможно?


vbscript usb-drive
person Inside Man    schedule 17.02.2015    source источник
comment
Вы определили, что должен делать код, если USB-накопитель подключен к папке без буквы диска?   -  person MC ND    schedule 17.02.2015
comment
Мне также нужен формат USB-накопителя NTFS или FAT, что невозможно с первым скриптом. Оба скрипта имеют некоторые функции, которые мне нужны для их объединения.   -  person Inside Man    schedule 17.02.2015

Ответы (2)


arrow_upward
3
arrow_downward

Попробуйте этот код:

'Show drive letters associated with each
ComputerName = "."
Set wmiServices  = GetObject ( _
    "winmgmts:{impersonationLevel=Impersonate}!//" _
    & ComputerName)
' Get physical disk drive
Set wmiDiskDrives =  wmiServices.ExecQuery ( "SELECT Caption, DeviceID FROM Win32_DiskDrive WHERE InterfaceType = 'USB'")

For Each wmiDiskDrive In wmiDiskDrives
   ' x = wmiDiskDrive.Caption & Vbtab & " " & wmiDiskDrive.DeviceID 
    'Use the disk drive device id to
    ' find associated partition
    query = "ASSOCIATORS OF {Win32_DiskDrive.DeviceID='" & wmiDiskDrive.DeviceID & "'} WHERE AssocClass = Win32_DiskDriveToDiskPartition"    
    Set wmiDiskPartitions = wmiServices.ExecQuery(query)

    For Each wmiDiskPartition In wmiDiskPartitions
        'Use partition device id to find logical disk
        Set wmiLogicalDisks = wmiServices.ExecQuery ("ASSOCIATORS OF {Win32_DiskPartition.DeviceID='" _
             & wmiDiskPartition.DeviceID & "'} WHERE AssocClass = Win32_LogicalDiskToPartition") 
x = ""
        For Each wmiLogicalDisk In wmiLogicalDisks
            x = x & wmiDiskDrive.Caption & " " & wmiDiskPartition.DeviceID & " = " & wmiLogicalDisk.DeviceID
Wscript.echo x

        Next      
    Next
Next
person Hackoo    schedule 17.02.2015
comment
Есть ли способ пропустить внешние жесткие диски? - person Inside Man; 17.02.2015

arrow_upward
1
arrow_downward

Получите желаемый результат из следующего скрипта (с комментариями по мере необходимости и понятным выводом). Написано для запуска с хостом wscript или cscript)

' VB Script Document 28556806.vbs
option explicit
On Error Goto 0

Dim ComputerName, strRslt, strQuery
Dim wmiServices _
  , wmiDiskDrives, wmiDiskDrive _
  , wmiDiskPartitions, wmiDiskPartition _
  , wmiLogicalDisks, wmiLogicalDisk

strRslt = Wscript.ScriptName _
    & vbTab & "Drive letters associated with disk drives" _ 

ComputerName = "."

Set wmiServices  = GetObject ( _
    "winmgmts:{impersonationLevel=Impersonate}!//" _
    & ComputerName)
' Get physical disk drive
Set wmiDiskDrives =  wmiServices.ExecQuery ( _
    "SELECT Caption, DeviceID, InterfaceType FROM Win32_DiskDrive")

For Each wmiDiskDrive In wmiDiskDrives
    strRslt = strRslt & vbNewLine
    strRslt = strRslt & vbNewLine _
      & "DiskDrive.Caption = " & wmiDiskDrive.Caption _ 
      & vbNewLine & "DiskDrive.InterfaceType = " _
          & wmiDiskDrive.InterfaceType

    'Use the disk drive device id to find associated partition
    strQuery = "ASSOCIATORS OF {Win32_DiskDrive.DeviceID='" _
        & wmiDiskDrive.DeviceID _
        & "'} WHERE AssocClass = Win32_DiskDriveToDiskPartition"    
    Set wmiDiskPartitions = wmiServices.ExecQuery(strQuery)

    For Each wmiDiskPartition In wmiDiskPartitions
        'Use partition device id to find logical disk
        Set wmiLogicalDisks = wmiServices.ExecQuery _
            ("ASSOCIATORS OF {Win32_DiskPartition.DeviceID='" _
             & wmiDiskPartition.DeviceID _
             & "'} WHERE AssocClass = Win32_LogicalDiskToPartition") 

        For Each wmiLogicalDisk In wmiLogicalDisks
            strRslt = strRslt _
              & vbNewLine & "DiskDrive.Caption = " _
                  & wmiDiskDrive.Caption _
              & vbNewLine & "DiskDrive.DeviceID = " _
                  & wmiDiskDrive.DeviceID _
              & vbNewLine & "DiskPartition.Partition = " _
                  & wmiDiskPartition.DeviceID _
              & vbNewLine & "LogicalDisk.DeviceID = " _
                  & wmiLogicalDisk.DeviceID 
        Next      
    Next
Next

WScript.Echo strRslt

Я задумал свой ответ в более широком подходе, чтобы упростить выбор среди подключенных USB-накопителей; соответствующие свойства можно найти в Класс аппаратного обеспечения компьютерной системы

person JosefZ    schedule 17.02.2015