Как выйти из режима vimdiff в vim, особенно для Fugitive?

Вы можете выполнить windo set nodiff noscrollbind, а затем закрыть второе окно.

Обновление: есть команда diffoff. Используйте windo diffoff, а не то, что я написал в предыдущей строке.

Согласно: https://github.com/tpope/vim-fugitive/issues/36

Закройте другое окно. Самый простой способ сделать это, если вы не переместили на него фокус, - <C-W><C-O>, что означает «сделать это окно единственным окном».

Мне не повезло с diffoff, но я только что узнал, что :Gedit без аргументов вернет вас к версии файла для рабочего каталога, в отличие от какой-то более ранней версии, которую вы просматривали.

И поскольку q (не требуется :q) закроет боковую панель diff, вы можете сделать q, а затем :Gedit, чтобы избавиться от боковой панели, а затем вернуться к текущей версии файла.

Это отлично работает для меня, здесь объединены некоторые из существующих идей:

function! MyCloseDiff()
  if (&diff == 0 || getbufvar('#', '&diff') == 0)
        \ && (bufname('%') !~ '^fugitive:' && bufname('#') !~ '^fugitive:')
    echom "Not in diff view."
    return
  endif

  " close current buffer if alternate is not fugitive but current one is
  if bufname('#') !~ '^fugitive:' && bufname('%') =~ '^fugitive:'
    if bufwinnr("#") == -1
      b #
      bd #
    else
      bd
    endif
  else
    bd #
  endif
endfunction
nnoremap <Leader>gD :call MyCloseDiff()<cr>

Я нашел для этого простое решение. Вы можете проверить это здесь: https://gist.github.com/radmen/5048080

" Simple way to turn off Gdiff splitscreen
" works only when diff buffer is focused
if !exists(":Gdiffoff")
  command Gdiffoff diffoff | q | Gedit
endif

Ни одно из вышеперечисленных решений не помогло мне. Вместо этого закончил делать это:

nnoremap <Leader>D :Gedit<CR><C-w>h :q<CR><C-w>k

Альтернативой <C-W><C-O>, если у вас несколько окон, было бы перемещение в другое окно сравнения и выполнение <C-W>c, которое закрывает только одно окно.

Если вы закроете неправильное окно сравнения, сделайте :Gedit

Будьте осторожны и не путайте <C-W>c с <C-W><C-C>

это то, что я должен оставить в окнах vimdiff после использования: Gdiff

nnoremap gD :q!<CR> :Gedit!<CR>

noremap <leader>do :diffoff \| windo if &diff \| hide \| endif<cr>

Довольно режим различий и закройте другие окна различий. (Примечание: беглец автоматически удалит свои скрытые буферы.)

Моя функция будет работать как из окна сравнения, так и из окна файла. Но, вероятно, не справится с несколькими открытыми различиями. Для этого вам нужно использовать fugitive#buffer(n).path() для сканирования и сопоставления.

command! Gdiffoff call Gdiffoff()
function! Gdiffoff()
    let diffbufnr = bufnr('^fugitive:')
    if diffbufnr > -1 && &diff
        diffoff | q
        if bufnr('%') == diffbufnr | Gedit | endif
        setlocal nocursorbind
    else
        echo 'Error: Not in diff or file'
    endif
endfunction

Добавьте привязку клавиш:

nnoremap <silent> <leader>gD :Gdiffoff<CR>

Еще один способ. То, что у меня есть в fugitive.vim - сначала сохраните некоторую информацию (s: gitbufname) при запуске diff:

function! s:Diff(vert,...) abort
  call sy#toggle()
  let s:startcol = winwidth(0)
  let &columns=(winwidth(0) * 2 - 20)
...
    if getwinvar('#', '&diff')
      let s:gitbufname = bufname("%")
      wincmd p
      call feedkeys(winnr."\<C-W>w", 'n')
    endif
...
endfunction

и позже при выходе из окна переключения буфера на сохраненный буфер и восстановление:

augroup fugitive_diff
autocmd!
autocmd BufWinLeave *
  \ if s:can_diffoff(+expand('<abuf>')) && s:diff_window_count() == 2 |
  \   if exists('s:gitbufname') && winnr() != bufwinnr(s:gitbufname) |
  \     let nr = bufnr("%") | exe bufwinnr(s:gitbufname).'wincmd w' | exe 'buf'.nr |
  \   endif |
  \   call s:diffoff_all(getbufvar(+expand('<abuf>'), 'git_dir')) |
  \   call sy#toggle() |
  \   call airline#load_theme() | call airline#update_statusline() |
  \   let &columns=s:startcol |
  \ endif
...

Проверьте vimdiff переключение между diffthis и diffoff здесь, на этой странице.

Код:

nnoremap <silent> <Leader>df :call DiffToggle()<CR>

function! DiffToggle()
    if &diff
        diffoff
    else
        diffthis
    endif
:endfunction

Способ 1:

• открыть сравнение по:

:windo diffthis

• закрыть его:

:windo diffoff

Способ 2:

Я рекомендую использовать самую простую команду: :q<CR>

если вы хотите сделать это быстро, добавьте отображение:

" Set mapleader
let mapleader = ","
let g:mapleader = ","

и

" Quickly close the current window
nnoremap <leader>q :q<CR>

У меня это хорошо работает. Выйдите из vimdiff только через ,q, потому что обычно ваш курсор находится в старом файле.

Использовал приведенный ниже код на основе https://stackoverflow.com/a/15113951/10999673:

    if !exists(":Gdiffoff")
        command Gdiffoff bw! fugitive://*
    endif

но это дало мне ошибку "E93: более одного совпадения для ..." в трехстороннем различии, поэтому я вместо этого использовал ответ от https://stackoverflow.com/a/4867969/10999673 и, наконец, получите следующее:

function! GetBufferList()
    return filter(range(1,bufnr('$')), 'buflisted(v:val)')
endfunction

function! GetMatchingBuffers(pattern)
    return filter(GetBufferList(), 'bufname(v:val) =~ a:pattern')
endfunction

function! WipeMatchingBuffers(pattern)
    let l:matchList = GetMatchingBuffers(a:pattern)

    let l:count = len(l:matchList)
    if l:count < 1
        echo 'No buffers found matching pattern ' . a:pattern
        return
    endif

    if l:count == 1
        let l:suffix = ''
    else
        let l:suffix = 's'
    endif

    exec 'bw ' . join(l:matchList, ' ')

    echo 'Wiped ' . l:count . ' buffer' . l:suffix . '.'
endfunction

command! -nargs=1 Gdiffoff call WipeMatchingBuffers('fugitive://')

Я просто настроил, скопировал и вставил код в свой .vimrc

Выполнение :Gwrite после слияния удовлетворительно закроет две другие панели различий в дополнение к обновлению кеша git, чтобы пометить файл как объединенный.