Ошибка AWK - синтаксическая ошибка в grep или рядом с ним

оболочка — это среда, из которой можно вызывать инструменты UNIX, с языком для последовательности этих вызовов.

grep — это инструмент UNIX для печати строк из файлов (или конвейеров), соответствующих регулярным выражениям.

awk — это стандартный универсальный инструмент UNIX для обработки текста.

Это 3 совершенно разных инструмента со своими языками/синтаксисом.

Вы должны вызвать grep из оболочки, чтобы найти регулярное выражение и напечатать соответствующую строку.

Вы бы вызывали awk из оболочки для выполнения более сложных операций по манипулированию текстом, которые могут включать или не включать что-либо, что может сделать grep.

Вы НЕ будете вызывать grep из awk, и вы НЕ МОЖЕТЕ вызывать awk из grep.

Вы можете вызывать оболочку из awk в некоторых очень редких ситуациях, когда это полезно, но вы не можете вызывать оболочку из grep.

Вы опубликовали пример ввода в своем вопросе, теперь обновите его, чтобы показать конкретный вывод, который вы хотели бы получить в результате запуска инструмента на этом вводе, чтобы мы могли помочь вам написать инструмент для этого.

Если это полезно, вот правильный синтаксис awk для скрипта awk, чтобы делать то, что вы пытаетесь сделать с эхом, grep и т. д.:

$ cat tst.awk
{
    if (/\|__/) {
        print "Child USB Port: ",$3
    }
    else {
        print $3
        var = $3
        gsub(/[^[:digit:]]/,"",var)
        print var
    }
}
$
$ awk -f tst.awk file
02.Port
02
Child USB Port:  4:
Child USB Port:  6:
Child USB Port:  6:
01.Port
01

Учитывая ваш обновленный вопрос:

$ cat tst.awk
{
    var = $3+0
    if (/\/:/) {
        bus = var
    }
    else {
        print bus "-" var
    }
}
$
$ awk -f tst.awk file
2-4
2-6
2-6

Обратите внимание: если вы хотите, чтобы это перешло к паре файлов, а также к стандартному выводу, тогда все, что вам нужно вместо последующего эха + канала + тройника, это:

BEGIN{
    path   = "/sys/bus/usb/drivers/usb/"
    unbind = path "unbind"
    bind   = path "bind"
}
{
    var = $3+0
    if (/\/:/) {
        bus = var
    }
    else {
        busPort = bus "-" var
        print busPort
        print busPort > unbind
        print busPort > bind
    }
}

и поскольку кажется бессмысленным повторять действие для уже обработанных комбинаций шина+порт (например, второй 2-6):

BEGIN{
    path   = "/sys/bus/usb/drivers/usb/"
    unbind = path "unbind"
    bind   = path "bind"
}
{
    var = $3+0
    if (/\/:/) {
        bus = var
    }
    else {
        busPort = bus "-" var
        if (!seen[busPort]++) {
            print busPort
            print busPort > unbind
            print busPort > bind
        }
    }
}

Вы не можете определить переменную внутри awk

var= $(echo $3 | grep -o "[1-9]"

Сделайте вот так:

awk -v var=$(echo $3 | grep -o "[1-9]" '{print var}' file

PS Не понимаю, почему нужно использовать и awk, и grep