Как перечислить объекты в TObjectList?

Чтобы ответить на конкретный вопрос, это пример введения счетчика. Обратите внимание, что вам придется создать потомка TObjectList, чтобы добавить функцию GetEnumerator. Вы могли бы обойтись без создания подклассов с помощью вспомогательного класса, но я оставлю это в качестве упражнения для заинтересованного читателя.

type

TObjectListEnumerator = record
private
  FIndex: Integer;
  FList: TObjectList;
public
  constructor Create(AList: TObjectList);
  function GetCurrent: TObject;
  function MoveNext: Boolean;
  property Current: TObject read GetCurrent;
end;

constructor TObjectListEnumerator.Create(AList: TObjectList);
begin
  FIndex := -1;
  FList := AList;
end;

function TObjectListEnumerator.GetCurrent;
begin
  Result := FList[FIndex];
end;

function TObjectListEnumerator.MoveNext: Boolean;
begin
  Result := FIndex < FList.Count - 1;
  if Result then
    Inc(FIndex);
end;

//-- Your new subclassed TObjectList

Type

TMyObjectList = class(TObjectList)
  public
    function GetEnumerator: TObjectListEnumerator;
end;

function TMyObjectList.GetEnumerator: TObjectListEnumerator;
begin
  Result := TObjectListEnumerator.Create(Self);
end;

Эта реализация перечислителя использует запись вместо класса. Преимущество этого заключается в том, что при выполнении for..in перечислений в куче не выделяется дополнительный объект.

procedure TfrmCustomerLocator.OnBatchDataAvailable(BatchList: TObjectList);
var
   o: TObject;
begin
   for o in TMyObjectList(BatchList) do // A simple cast is enough in this example
   begin
      //...snip...where we do something with (o as TCustomer)
   end;
end;   

Как уже отмечали другие, существует класс дженериков, который лучше использовать, TObjectList<T>.

Используя дженерики, вы можете иметь типизированный список объектов (только что заметил комментарий, но все равно закончу это)

И если вы ищете вескую причину для использования TObjectList<T>, эта причина будет заключаться в том, что это сэкономит вам много приведения типов в вашем коде.

program Project1;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.SysUtils, Generics.Collections;
Type
  TCustomer = class
  private
  public
    //Properties and stuff
  end;

var
    list: TObjectlist<TCustomer>;
    c: TCustomer;
begin
    list := TObjectList<TCustomer>.Create;
    for c in list do
    begin
        //nothing
    end;
end.

Перечислитель для TObjectList объявлен в TList, который является классом, производным от которого является TObjectList. RTL не удосуживается объявить более конкретный перечислитель для TObjectList. Итак, у вас остался счетчик TList. Что дает предметы типа Pointer, которые относятся к типу предметов, хранящихся у TList.

Вероятно, есть несколько причин, по которым разработчики RTL решили ничего не делать с TObjectList. Например, я полагаю следующие возможные причины:

1. TObjectList, как и все в Contnrs, объявлено устаревшим из-за универсальных контейнеров в Generics.Collections. Зачем тратить ресурсы на изменение устаревшего класса.
2. Даже если бы у TObjectList был счетчик, который выдал TObject элементов, вам все равно пришлось бы их разыгрывать. Будет ли нумератор, выдающий TObject, действительно более полезным?
3. Разработчики просто забыли о существовании этого класса, когда добавляли перечислители.

Что вы должны сделать. Очевидный выбор — использовать TList<T> или TObjectList<T> из Generics.Collections. Если вы хотите сохранить TObjectList, вы можете подклассировать его и добавить перечислитель, который дал TObject. Если вы не знаете, как это сделать, вы можете узнать, как это сделать, из документация. Или вы можете использовать унаследованный перечислитель и ввести указатели, которые он дает.

Мне кажется, что, поскольку вы готовы изменить код с индексированного цикла for на цикл for in, это означает, что вы готовы внести нетривиальные изменения в код. В этом случае универсальный контейнер кажется очевидным выбором.