Локальный макрос Stata не определен

Это работает:

local  cuts      0 15 32 50
local  mycut     32
local  myposn    : list posof "`mycut'" in cuts

local  mynewcut  : word `=`myposn'-1' of `cuts'
display "`mynewcut'"

Вам нужно оценить арифметическую операцию, используя =. У вас также отсутствуют кавычки при обращении к локальному cuts.

Попытка использовать макрос, который не был определен, не считается ошибкой Stata. Это элемент языкового дизайна. Также обратите внимание, что (по крайней мере) один из ваших нежелательных синтаксисов

local  mynewcut  : word `=`myposn'-1' of cuts

не является незаконным, поэтому в таких случаях следует проявлять осторожность. После of Stata ожидает только какую-то строку, а cuts считается строкой. Это будет работать нормально:

local  mynewcut  : word 2 of cuts cuts2 cuts3
display "`mynewcut'"

но, может быть, не так, как ожидалось. Все меняется, когда добавляются кавычки. Stata теперь знает, что должна выполнить операцию замены макроса.

Обычно я внимательно присматриваюсь к местным жителям, прежде чем запускать их в «производство». Но вы могли бы использовать assert. Например:

local  cuts      0 15 32 50
local  mycut     32
local  myposn    : list posof "`mycut'" in cuts
display "`myposn'"

local  mynewcut  : word `=`myposn'-1' of cuts
display "`mynewcut'"

assert "`mynewcut'" != ""

Роберто дал хороший подробный ответ, но в дополнение давайте попробуем обзор здесь. Решающее значение имеет то, что именно вы понимаете под fail и есть ли смысл, в котором Стата может согласиться с вами.

Удаление существующего локального макроса и присвоение пустой строки (потенциальному) имени локального макроса имеет тот же эффект, что и Stata. Если я пойду

local foo = 42 
local foo 

or

local bar 

процесс отличается по своей сути, но конечный результат похож. В первом случае локальный макрос foo исчезает, а во втором случае локальный макрос bar никогда не создается. Второй случай не бесполезен, так как (например) программист часто хочет прояснить, что локальный макрос изначально пуст (за исключением того, что это не совсем возможно) или что любой ранее созданный макрос с таким именем удален.

Короче говоря, Stata не различает, по крайней мере, с точки зрения пользователя, между пустым (локальным или глобальным) макросом и макросом, которого не существует. Это менее странно, если вы понимаете, что приведенные здесь определения вдохновлены оболочками операционной системы, а не языками обработки строк.

Но есть полезное последствие. Тест

if "`bar'" != "" 

является одновременно проверкой существования и проверкой непустоты локального макроса bar, а также применима к макросам с числовыми символами.

Кроме того, могут быть случаи, когда вы пытаетесь поместить непустую строку в макрос, делаете какую-то ошибку и заканчиваете тем, что назначаете пустую строку. Это может быть ошибкой программирования, но это не является незаконным с точки зрения Stata, как уже подразумевают приведенные выше примеры.

Полнота здесь неуловима, но еще один случай заключается в том, что определение макроса может быть недопустимым по другим причинам. Таким образом

local foo = lg(42)

потерпит неудачу, потому что нет функции lg(). С другой стороны,

local foo lg(42) 

будет преуспевать в том, что касается Stata, потому что никакая оценка не применяется, и поэтому Stata никогда не приходится работать lg(42). Макрос будет просто содержать lg(42) в качестве текста.