Как предотвратить вмешательство тональной функции Arduino Esplora в работу светодиода RGB

Я немного изучил документацию 32U4 и взял специфическую логику Esplora из библиотек Arduino, которые они используют для инициализации ресурсов PWM при запуске. Полученную ниже процедуру timerFix () можно использовать для восстановления правильных настроек.

void loop()
{
  Esplora.writeRGB(127,0,0);
  delay(1000);
  Esplora.tone(311);
  delay(1000);
  timerFix();
  Esplora.writeRGB(32,0,0);
  delay(1000);  
}
void timerFix()
{
  #define sbi(sfr,b) (_SFR_BYTE(sfr) |= _BV(b))

  //Tone will have hijacked the timer used for the 
  //RGB led RED channel so once we're done we need
  //to restore it.  First shutdown the tone internals
  //if not done already...
  Esplora.noTone();

  //Now clear the Timer Count Control Registers to
  //have them in a known state.
  TCCR3A = 0;
  TCCR3B = 0;

  //Setup the clock source - clk/64 
  sbi(TCCR3B, CS31);
  sbi(TCCR3B, CS30);

  //Set the wave form generator for 10-bit PWM
  sbi(TCCR3A, WGM30);

  //re-link the PWM timer to output channel
  //by passing something other than 0 and 255
  //so that the analogWrite function is forced to
  //recompute the correct value for either the
  //OCR3A or OCR3B register (output control register) 
  //as appropriate
  analogWrite(5, 1);

  //turn the LED channel off
  analogWrite(5, 0);
}

Ваши подозрения относительно tone() перенастройки таймера верны. На 32U4 таймер 3 используется для tone(), но на Esplora OC3A используется для красного компонента (OC1B и OC1A используются для зеленого и синего компонентов соответственно). Это означает, что каждый раз, когда tone() вызывается на Esplora, таймер 3 перенастраивается для CTC (WGM3 [3: 0] = 0b0100), тогда как красный компонент требует ШИМ для правильного использования (а analogWrite() специально использует 8-битную фазу -правильный ШИМ [WGM [3: 0] = 0b0001]). А поскольку таймер требуется до тех пор, пока не прекратится звуковой сигнал, нет разумного способа переключать его туда и обратно между режимами.

Обычно самый простой способ исправить это - сказать tone() использовать другой таймер. К сожалению, на Esplora нет таймера, который он мог бы использовать: таймер 0 используется delay() и др., Таймер 1 используется зеленым и синим компонентами, таймер 4 работает совершенно иначе, чем библиотеки Arduino. запрограммированы на, а таймер 2 даже не существует на 32U4.

Однако вывод для OC3A на 32U4 - это тот же вывод для nOC4A. Это означает, что вместо этого мы можем использовать таймер 4 для управления красным компонентом. Значения для TCCR4 * не были равны 0, когда вы их исследовали, но это может быть из-за того, что загрузчик возится с ними; Мне не удалось найти что-либо в ядре Arduino или библиотеке Esplora, что их изменяет.

Есть 2 проблемы с использованием таймера 4:

1. Вывод 13 подключен к OC4A. Это означает, что вывод 13 всегда должен быть настроен как вход, поскольку на выходе из него будет сигнал ШИМ, который имеет фазу, противоположную красной составляющей.

2. Библиотеки Arduino не запрограммированы для работы с таймером 4. Это означает, что нам потребуется доступ к таймеру 4 на низком уровне, чтобы настроить и использовать его.

И так:

pinMode(13, INPUT);
// disable timer 4 interrupts
TIMSK4 = 0;
// reset TCCR4C
TCCR4C = 0;
// set OCR4C to maximum
OCR4C=0xff;
// clear dead time register
DT4 = 0;
// enable PWM based on OCR4A and connect nOC4A (and OC4A)
TCCR4A = _BV(PWM4A) | _BV(COM4A0);
// match analogWrite() prescaling
TCCR4B = _BV(CS42) | _BV(CS41) | _BV(CS40);
// enable fast PWM
TCCR4D = 0;
// set minimum brightness
OCR4A = 0xff;

delay(1000);
OCR4A = 0xbf; // low brightness
delay(1000);
OCR4A = 0x3f; // high brightness
delay(1000);
OCR4A = 0x7f; // mid brightness
delay(1000);
OCR4A = 0x00; // max brightness