Как убрать фокус с текущего компонента?

Вы можете использовать:

procedure TCustomForm.DefocusControl(Control: TWinControl; Removing: Boolean);

Мы достигаем этого, устанавливая Self.ActiveControl := nil. Это приводит к срабатыванию всех событий выхода. В нашем случае мы также хотели снова сфокусироваться на элементе управления после того, как произошло сохранение. Это потребовало нескольких дополнительных проверок, чтобы убедиться, что у нас есть хороший контроль, который может принять фокус.

procedure TSaleEditor.SaveCurrentState();
var
  SavedActiveControl: TWinControl;
  AlternateSavedControl: TWinControl;
begin

  // Force the current control to exit and save any state.
  if Self.ActiveControl <> nil then
  begin
    SavedActiveControl := Self.ActiveControl;

    // We may have an inplace grid editor as the current control.  In that case we
    // will not be able to reset it as the active control.  This will cause the
    // Scroll box to scroll to the active control, which will be the lowest tab order
    // control.  Our "real" controls have names, where the dynamic inplace editor do not
    // find an Alternate control to set the focus by walking up the parent list until we
    // find a named control.
    AlternateSavedControl := SavedActiveControl;
    while (AlternateSavedControl.Name = '') and (AlternateSavedControl.Parent <> nil) do
    begin
      AlternateSavedControl := AlternateSavedControl.Parent;
    end;

    Self.ActiveControl := nil;

    // If the control is a radio button then do not re-set focus
    // because if you are un-selecting the radio button this will automatically
    // re-select it again
    if (SavedActiveControl.CanFocus = true) and
      ((SavedActiveControl is TcxRadioButton) = false) then
    begin
      Self.ActiveControl := SavedActiveControl;
    end
    else if (AlternateSavedControl.CanFocus = true) and
      ((AlternateSavedControl is TcxRadioButton) = false) then
    begin
      Self.ActiveControl := AlternateSavedControl;
    end;

  end;

end;

Посмотрите на TCustomForm.FocusControl. Вы не можете заставить его потерять фокус, не переключая фокус на что-то другое, но вы можете переключиться, а затем сразу же переключиться обратно, что, вероятно, сработает.

В оконном блоке есть функция SetFocus. Попробуй это:

Windows.SetFocus(0);