*.bmp теряет прозрачный фон при использовании элемента управления ImageList v6

Как только вы поместите растровое изображение с информацией об альфа-канале в список изображений, нет простого (*) способа получить его в исходной растровой форме. TImageList.GetBitmap просто устанавливает размеры растрового изображения, которое вы ему передаете, и рисует на своем холсте. Он не использует перегрузку, которая могла бы прозрачно рисовать BTW, но это не так важно, поскольку вместо использования GetBitmap вы можете сами вызвать перегрузку Draw.

В результате вместо потоковой передачи списка изображений я предлагаю передавать сами растровые изображения, если вам нужно сохранить их первоначальную форму.

Попробуйте следующее и посмотрите, соответствует ли оно вашим потребностям (оно прозрачно, но может не совпадать с исходным растровым изображением, поскольку оно снова рисуется):

var
  Bmp       : TBitmap;
  ImageList : TImageList;
  FS: TFileStream;
begin
  ImageList := TImageList.Create(nil);
    try
      FS := TFileStream.Create('c:\temp\1.cmp',fmOpenRead or fmShareDenyWrite);
      try
        FS.ReadComponent(ImageList);
      finally
        FS.Free;
      end;
      Bmp := TBitmap.Create;
      try
        Bmp.PixelFormat := pf32bit;
        Bmp.Canvas.Brush.Color := clNone;
        Bmp.Width := ImageList.Width;
        Bmp.Height := ImageList.Height;
        ImageList.Draw(Bmp.Canvas, 0, 0, 0, dsNormal, itImage);
        Bmp.SaveToFile('c:\temp\3.bmp');
      finally
        Bmp.Free;
      end;
  finally
    ImageList.Free;
  end;
end;

Я полагаю, я нашел своего рода решение.

var
  BMP: TBitmap;
  ImageList : TImageList;
  FS: TFileStream;
  ico: TIcon;
  IconInfo: TIconInfo;
begin
  ImageList := TImageList.Create(nil);
    try
      FS := TFileStream.Create('c:\temp\1.cmp',fmOpenRead or fmShareDenyWrite);
      try
        FS.ReadComponent(ImageList);
      finally
        FS.Free;
      end;
      Bmp := TBitmap.Create;
      Ico := TIcon.Create;
      try
        ImageList.GetIcon(0, ico);

        GetIconInfo(ico.Handle, IconInfo);

        BMP.Handle := IconInfo.hbmColor;
        BMP.PixelFormat := pf32bit;
        BMP.Canvas.Brush.Color := clNone;

        Bmp.SaveToFile('c:\temp\3.bmp');
      finally
        ico.Free;
        Bmp.Free;
      end;
  finally
    ImageList.Free;
  end;
end;

Этот код получит точно такое же растровое изображение, которое было помещено в ImageList;

Чтобы скопировать один ImageList в другой без потерь, мы можем использовать копирование с потоками:

procedure TbtkImageList.Assign(Source: TPersistent);
var
  IL: TCustomImageList;
  BIL: TbtkImageList;
var
  st: TMemoryStream;
begin
  st := TMemoryStream.Create;
  try
    st.WriteComponent(TbtkImageList(Source));
    st.Seek(0, soFromBeginning);
    st.ReadComponent(Self);
  finally
    st.Free;
  end;
end;