Передача переменной из формы в модуль в VBA

Не объявляйте переменную в пользовательской форме. Объявите его как Public в модуле.

Public pass As String

В форме пользователя

Private Sub CommandButton1_Click()
    pass = UserForm1.TextBox1
    Unload UserForm1
End Sub

В модуле

Public pass As String

Public Sub Login()
    '
    '~~> Rest of the code
    '
    UserForm1.Show
    driver.findElementByName("PASSWORD").SendKeys pass
    '
    '~~> Rest of the code
    '
End Sub

Возможно, вы захотите добавить дополнительную проверку непосредственно перед вызовом линии driver.find...?

If Len(Trim(pass)) <> 0 Then

Это гарантирует, что пустая строка не будет передана.

Ответ Сиддхарта хорош, но он полагается на глобальные переменные. Есть лучший способ, более дружественный к ООП.

UserForm - это модуль класса, как и любой другой, с той лишь разницей, что у него есть скрытый атрибут VB_PredeclaredId, установленный на True, что заставляет VB создавать объектную переменную с глобальной областью видимости, названную в честь класса - вот как вы можете писать UserForm1.Show без создания нового экземпляр класса.

Отойдите от этого и вместо этого рассматривайте свою форму как объект - выставляйте Property Get члены и абстрагируйте элементы управления формы - вызывающий код в любом случае не заботится о элементах управления:

Option Explicit
Private cancelling As Boolean

Public Property Get UserId() As String
    UserId = txtUserId.Text
End Property

Public Property Get Password() As String
    Password = txtPassword.Text
End Property

Public Property Get IsCancelled() As Boolean
    IsCancelled = cancelling
End Property

Private Sub OkButton_Click()
    Me.Hide
End Sub

Private Sub CancelButton_Click()
    cancelling = True
    Me.Hide
End Sub

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
    If CloseMode = VbQueryClose.vbFormControlMenu Then
        cancelling = True
        Cancel = True
        Me.Hide
    End If
End Sub

Теперь вызывающий код может это сделать (при условии, что пользовательская форма была названа LoginPrompt):

With New LoginPrompt
    .Show vbModal
    If .IsCancelled Then Exit Sub
    DoSomething .UserId, .Password
End With

Где DoSomething - это некоторая процедура, требующая двух строковых параметров:

Private Sub DoSomething(ByVal uid As String, ByVal pwd As String)
    'work with the parameter values, regardless of where they came from
End Sub