Автофильтр Excel VBA все, кроме трех

Помните, что цель состоит в том, чтобы удалить несовпадающие строки; Автофильтр - это лишь один из инструментов, помогающих достичь цели. Если автофильтр вам не подходит, выберите другой метод. Рассмотреть возможность:

Sub AllBut()
    Dim rTable As Range, r As Range
    Dim rDelete As Range
    Set rTable = Selection
    Set rDelete = Nothing
    For Each r In rTable.Columns(7).Cells
        v = r.Value
        If v <> "101" And v <> "102" And v <> "103" Then
            If rDelete Is Nothing Then
                Set rDelete = r
            Else
                Set rDelete = Union(r, rDelete)
            End If
        End If
    Next

    If Not rDelete Is Nothing Then rDelete.EntireRow.Delete
End Sub

Здесь мы выбираем блок данных для обработки (не включая строку заголовка). Макрос просматривает столбец № 7 этого блока и удаляет все строки, не соответствующие критериям.

Все, что останется, - это модели 101, 102 и 103.

Поскольку речь шла о методе автофильтрации, я предлагаю вверх по этому методу с использованием объекта Scripting.Dictionary для имитации процедура, которая использовалась бы, если бы это выполнялось на листе вручную.

На рабочем листе пользователь применил бы Автофильтр, а затем использовал бы выпадающий столбец G, чтобы «отключить» значения 101, 102 и 103. То, что осталось, будет удалено. В VBA мы можем получить весь столбец G и заполнить объект словаря значениями, отличными от 101, 102 или 103, и использовать это в качестве критерия для операции фильтрации.

Sub filterNotThree()
    Dim d As Long, dDELs As Object, vVALs As Variant

    Set dDELs = CreateObject("Scripting.Dictionary")

    With Worksheets("Sheet6")
        If .AutoFilterMode Then .AutoFilterMode = False
        With .Cells(1, 1).CurrentRegion
            'grab all of column G (minus the header) into a variant array
            vVALs = .Resize(.Rows.Count - 1, 1).Offset(1, 6).Value2

            'populate the dictionary object with the values that are NOT 101, 102, or 103
            For d = LBound(vVALs, 1) To UBound(vVALs, 1)
                Select Case vVALs(d, 1)
                    Case 101, 102, 103
                        'do not add
                    Case Else
                        'not a match, add it to the delete list
                        'the AutoFilter criteria needs to be text
                        ' so we set the Keys as text and the Items as numbers
                        dDELs.Item(CStr(vVALs(d, 1))) = vVALs(d, 1)
                End Select
            Next d

            'check to make sure there is something to filter on
            If CBool(dDELs.Count) Then
                'filter on the dictionary keys
                .AutoFilter field:=7, Criteria1:=dDELs.keys, Operator:=xlFilterValues

                'delete the visible rows (there has to be some)
                .Resize(.Rows.Count - 1, .Columns.Count).Offset(1, 0).EntireRow.Delete
            End If

        End With
        If .AutoFilterMode Then .AutoFilterMode = False
    End With

    dDELs.RemoveAll: Set dDELs = Nothing
End Sub

^{Данные до подпроцедуры filterNotThree}

^{Данные после подпроцедуры filterNotThree}

Я делал что-то подобное, но для двух полей, и этот синтаксис у меня работал:

myrange.AutoFilter Field:=7, Criteria1:="<>101", Operator:=xlAnd, Criteria2:="<>102", Operator:=xlAnd

Надеюсь, это поможет.

Я знаю, что это поздно, но если вам нужно более двух критериев, вы должны использовать массив.

myrange.AutoFilter Field:=7, Criteria1:=Array("<>101", "<>102", "<>103"), Operator:=xlFilterValues