Невозможно завершить потоки

Это полное неправильное использование рабочего потока. Вы делегируете всю работу потока основному потоку, делая рабочий поток бесполезным. Вместо этого вы могли бы использовать простой таймер.

Вместо этого правильное использование рабочего потока будет выглядеть примерно так:

type
  test = class(TThread)
  private
    { Private declarations }
  protected
    procedure Execute; override;
  end;

var
  Form1: TForm1;
  a: test = nil;

implementation

{$R *.dfm}

procedure test.Execute;
var
  I: integer
begin
  Synchronize(
    procedure begin    
      form1.ProgressBar1.Position := 0;
    end
  );

  for I := 1 to 5 do
  begin
    if Terminated then Exit;
    Sleep(1000);
    if Terminated then Exit;
    Synchronize(
      procedure begin
        Form1.ProgressBar1.Position := I * 20;
      end
    );
  end;

  Synchronize(
    procedure begin
      form1.ProgressBar1.Position := 100;    
    end
  );
end;

procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  btn_stopClick(nil);
end;

procedure TForm1.btn_startClick(Sender: TObject);
begin
  if a = nil then
    a := test.Create(False);
end;

procedure TForm1.btn_stopClick(Sender: TObject);
begin
  if a = nil then Exit;
  a.Terminate;
  a.WaitFor;
  FreeAndNil(a);
end;

Проблема в том, что поток ожидает, используя Sleep. Этот метод удерживает поток в спящем режиме в течение указанного времени, независимо от того, что происходит вокруг него. Чтобы иметь возможность «разорвать сон», вы должны использовать событие. Код следует изменить на этот:

procedure test.Execute;
begin
  Synchronize(procedure begin    
      form1.ProgressBar1.position := 0;
  end);
  Event.WaitFor(5000);
  if not IsTerminated then
    Synchronize(procedure begin    
        form1.ProgressBar1.position := 100;    
    end);
end;

Событие должно быть создано и уничтожено следующим образом:

constructor test.Create(aCreateSuspended: Boolean);
begin
  inherited;
  Event := TSimpleEvent.Create;
end;

destructor test.Destroy;
begin
  FreeAndNil(Event);
  inherited;
end;

Чтобы остановить поток, код:

procedure TForm1.btn_stopClick(Sender: TObject);
begin
  a.Terminate;
end;

Но простой вызов Terminate не сигнализирует о Событии, поэтому нам нужно переопределить Terminate:

procedure test.Terminate;
begin
  inherited;
  Event.SetEvent;
end;

Вызов SetEvent будет сигнализировать о событии, поэтому он разбудит поток. Выполнение продолжается в следующей строке, которая проверяет завершение потока и решает, выполнять вторую часть кода или нет.