cfloop над массивом/списком не разрешает ссылаться на предыдущие значения

Начал это как комментарий, но быстро стал слишком длинным. Я обычно использую счетчик, как вы упомянули. Я не думаю, что у ColdFusion есть встроенный способ справиться с этим за вас. Если вас беспокоит только сравнение текущего значения с предыдущим значением, я делал что-то подобное раньше:

<cfset previousValue = "">
<cfloop array = #myarray# index = "value">
    <cfif mystruct[value] GT 5>
        <!--- do something --->
    </cfif> 
    <cfif value NEQ previousValue>
        <!--- do something --->
    </cfif>
    <cfset previousValue = value>
</cfloop>

Вы обнаружили недостаток в реализации зацикливания массива в ColdFusion: индекс/позиция в массиве просто недоступны.

Я поднял этот вопрос в Adobe, а также аналогичный сбой в arrayEach().

Обо всем этом понятии можно прочитать «интересное» на Блог Эндрю Скотта, где обсуждаются различные мнения (и различия в них).

Между прочим, Railo делает все это правильно, как я писал на мой собственный блог.

Суть в том, что вам нужно поддерживать свой собственный счетчик, как вы намекаете, и @Miguel-F подтверждает.

Голосуйте за ошибки... возможно, Adobe исправит их в ColdFusion 11...

Позвольте мне попытаться исправить ваш второй пример и сделать его более читабельным...

<cfloop from="1" to="#ArrayLen(myarray)#" index="i">
  <cfset value = myarray[i]>
  <cfif mystruct[value] GT 5>
    ... do something
  </cfif>
  <cfset lastIndex = i - 1>
  <cfif lastIndex AND value NEQ myarray[lastIndex]>
    ... do something
  </cfif>
</cfloop>

Давайте подумаем об этом по-другому. Если мы перепишем их в cfscript для наглядности:

  myArray=[ 'xyz', 'yyy', '232', 'uoiu', 'youneedthis', '2343'];
    writedump(myArray);
    myLongStringThing = '';

    // LOOP OVER AN INDEX AND MANUALLY PUSH YOUR ARRAY ALONG
    for ( i = 1; i <= myArray.size(); i++) {
      v = myArray[i];
      if(i < 5 && i > 1 && myArray[i] != myArray[i-1]   ){
        x = doSomethingComplicated(v);
        myArray[i] = x; // Your new computed value
      }

      if(i > 1 && v != myArray[i-1] ) {
        y = somethingElseCool(v);
        myLongStringThing &= y;
      }
    }

    writedump(myArray);
    writeoutput(myLongStringThing & '<br>');

    // LOOP THE VALUES IN THE STRUCT/ARRAY 
    i = 0;
    for (k in myArray) {
      i++;
      writeoutput('k:' & k & '<br>');
      writeoutput('a[i]:' & myArray[i] & '<br>');
    }

    function doSomethingComplicated(v) {
      Arguments.v &= 'you did it!';
      return Arguments.v;
}

    function somethingElseCool(v) {
      Arguments.v &= ';';
      return Arguments.v;
    }

    // LOOPING A STRUCT IS DIFFERENT
    myStruct = {'asdf' = 234234, 'sdfsd' = 9798, 'oiujlkj3' = 'kohjkjh'};
    for (k in myStruct) {
      writeoutput('kinstruct:' & k & '<br>');
      writeoutput('kinstruct:' & myStruct[k] & '<br>');
    }

Если мы рассмотрим сигнатуру атрибута cfloop так же, как использование for(counter;condition;incrementor) и for(valuekey in object), мы увидим, что это примерно одно и то же.

Вы можете выбрать, как перебирать ваш объект (массив), но вы не можете выбрать версию только для значения, и текущие итераторы отслеживают индекс для вас.

Поэтому, если вам нужно отслеживать ваш предыдущий/следующий индекс, вам нужно выбрать метод итератора, который позволяет индекс (даже если это делается вручную).

NB: для массива вы, вероятно, можете смешивать/сопоставлять значение ключа с ручным итератором (стиль for(k in obj)), но когда используется структура, это фактическое имя KEY возвращается в 'k'. Не значение итерируемого массива. Это соответствует сигнатуре атрибута cfloop для зацикливания коллекции (например, структуры).

Я думаю, вы просите cfloop позволить вам установить маркер атрибута как значения, так и индекса. И я понимаю, что другие языки (и диалекты) могут это делать, но пока что в CF нет.

Пограничные случаи легко обрабатываются с помощью составного оператора if.

Вы можете использовать точно такую ​​же составную логику в операторах if в тегах, чтобы учитывать крайние случаи.

Вы могли заметить, что я использовал size() вместо ArrayLen(). Существует несколько операторов Java, которые можно использовать с массивами. Однако, насколько я могу судить, ни один из них не дает вам «курсор» или индекс данного состояния.

Если вы хотите еще немного углубиться в массивы, вы можете создать java-версию массива и сделать еще несколько вещей:

myArray = CreateObject( "java", "java.util.ArrayList" );
writeDump(myArray);  // This will show you the java object, which needs to be 'inited' still.
myArray = myArray.init(); // It returns the array, it does not act on the orig obj.
// You can now access the vast majority of java methods (including the parent methods)
myArray.add('myFirstValue');
myArray.add('my2ndValue');
myArray.add('yetAnotherValue');
writeDump(myArray);// This will look like a regular array dump
// You can also apply regular CF functions to this array like arrayAppend().
x = myArray.get(1); // This is a java index, so it begins at 0 which is the 1st elem. 1 is 2nd, etc.
writeOuput('At java index 1 we have:' & x & '<br>');

Вы можете поиграть с некоторыми из них, но насколько я могу судить, ни один из них не вернет пригодный для использования курсор или индекс. Однако некоторые из них могут оказаться полезными, например, subList() и equals().

В конечном счете, если вы хотите найти индекс без ручного индекса, вы можете сделать это:

index = arrayFind(myArray, v)

Что, конечно, является просто поиском индекса по значению, при условии, что значение уникально. Использование одного из методов цикла, который использует индекс, кажется более безопасным, чем пытаться выяснить, где вы находитесь постфактум.

Если вы используете CF 10 или Railo 4, вы можете использовать each() из библиотека Underscore.cfc для цикла с индексом:

_ = new Underscore();

_.each(myArray, function (value, index) {
   // loop code here
});

Я бы предложил использовать более выразительную функцию, например map() или reduce(), в зависимости от того, что вы пытаетесь выполнить с помощью цикла.

Примечание: я написал Underscore.cfc