Изменение значения пространства имен в преобразовании XSL?

Вы можете установить пространство имен для выходного элемента с помощью атрибута namespace:

<xsl:element name="{node-name(.)}" namespace="http://www.bar.org">
  // ...
</xsl:element>

Обратите внимание, что пространство имен должно быть URI, и хотя я полагаю, что вы это знаете, вероятно, будет хорошей идеей использовать URI в вашем примере.

Вот ссылка на отличный учебник по ZVON, в котором приведены рабочие примеры: http://www.zvon.org/xxl/XSLTreference/Output/xslt_element_namespace.html

Я согласен, что пространства имен сложны. Как вы знаете, префикс семантически не имеет значения, но многие системы позволяют вам выбирать префикс из эстетических соображений. Также обратите внимание на Saxon (http://saxon.sourceforge.net/)

EDIT Я думаю, вы найдете свой ответ здесь: пространство имен корневого тега XSLT вместо пространства имен атрибутов элемента

<xsl:stylesheet
  version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
  xmlns:ns1_src="some.url.01"
  xmlns:ns2_src="some.other.url"
  xmlns:ns3_src="another.one"
  xmlns="some.url.02"
  xmlns:ns2="some.other.url.02"
  xmlns:ns3="another.one.02"
>
  <!-- 
    Note that all the source namespaces got their own new "*_src" prefix. 
    The target namespaces take over the original prefixes. 
    "some.url.02" is the new global namespace.
  -->

  <xsl:output method="xml" version="1.0" encoding="UTF-8" standalone="yes" indent="yes"/>
  <xsl:strip-space elements="*"/>

  <!-- the identity template to copy everything, unless 
       it has been declared otherwise -->
  <xsl:template match="node() | @*">
    <xsl:copy>
      <xsl:apply-templates select="node() | @*" />
    </xsl:copy>
  </xsl:template>

  <!-- three templates to handle elements -->
  <xsl:template match="ns1_src:*">
    <xsl:element name="{local-name()}">
      <xsl:apply-templates select="node() | @*" />
    </xsl:element>
  </xsl:template>

  <xsl:template match="ns2_src:*">
    <xsl:element name="ns2:{local-name()}">
      <xsl:apply-templates select="node() | @*" />
    </xsl:element>
  </xsl:template>

  <xsl:template match="ns3_src:*">
    <xsl:element name="ns3:{local-name()}">
      <xsl:apply-templates select="node() | @*" />
    </xsl:element>
  </xsl:template>

  <!-- three templates to handle attributes -->
  <xsl:template match="@ns1_src:*">
    <xsl:attribute name="{local-name()}">
      <xsl:value-of select="." />
    </xsl:attribute>
  </xsl:template>

  <xsl:template match="@ns2_src:*">
    <xsl:attribute name="ns2:{local-name()}">
      <xsl:value-of select="." />
    </xsl:attribute>
  </xsl:template>

  <xsl:template match="@ns3_src:*">
    <xsl:attribute name="ns3:{local-name()}">
      <xsl:value-of select="." />
    </xsl:attribute>
  </xsl:template>

  <!-- timestamps will be ignored -->
  <xsl:template match="ns1_src:timestamp" />

</xsl:stylesheet>

Выход:

<order xmlns="some.url.02">
  <orderEntry>
    <orderControl>
      <mandant>test</mandant>
      <businessUnit>test</businessUnit>
      <inboundChannel>test</inboundChannel>
      <requestedDocuments>
        <ns2:document xmlns:ns2="some.other.url.02">orderForm</ns2:document>
      </requestedDocuments>
    </orderControl>
  </orderEntry>
</order>

<xsl:template match="a:*">
  <xsl:element name="{local-name()}"
               namespace="http://example.com/B">
    <xsl:copy-of select="@*" />
    <xsl:apply-templates />
  </xsl:element>
</xsl:template>

Он ищет любой элемент в пространстве имен с префиксом a и заменяет его элементом с тем же именем пространства имен http://example.com/B. Все атрибуты копируются «как есть», а затем оцениваются все дочерние элементы.

Добавьте свою пользовательскую обработку в или вокруг этого по мере необходимости.

Используете ли вы XSLT-задачу Ant для преобразования?

Если ответ «да», возможно, вы захотите перейти с механизма XSLT по умолчанию, который поставляется с Sun JDK 1.5+. Прочтите это.

Также прочтите эту статью о пространствах имен в XSLT.