Агрегатная функция для суммы и произведения в XPath

Подобно этому вопросу (http://stackoverflow.com/q/1333558/948404), я хочу использовать XPath для вычисления суммы по продуктам в такой структуре:

<items>
    <item>
        <value>1.0</value>
        <quantity>3</quantity>
    </item>
    <item>
        <value>2.5</value>
        <quantity>2</quantity>
    </item>
    <!-- ... -->
</items>

Есть ли выражение XPath, которое вычисляет сумму произведений каждого элемента value и quantity?

Обновление: решение должно работать с классом PHP XSLTProcessor, что означает, что оно, вероятно, должно быть совместимо с XSLT 1.0. Вот почему я еще не принял два, вероятно, правильных ответа, используя XSLT 2.0. Я не смог проверить их ни в своей реализации PHP, ни в своем браузере, ни в редакторе Tryit [1] от w3schools. Прости!

  1. http://w3schools.com/xsl/tryxslt.asp?xmlfile=cdcatalog&xsltfile=cdcatalog

xpath-1.0 xslt-1.0
person hielsnoppe    schedule 19.05.2012    source источник
comment
возможный дубликат XSLT для суммирования произведения двух атрибутов   -  person PeerBr    schedule 04.11.2014

Ответы (3)


arrow_upward
4
arrow_downward

Используйте это выражение XPath 2.0:

sum(/items/item/(value * quantity))

Вот преобразование XSLT 2.0 для проверки:

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>

    <xsl:template match="/">
        <xsl:sequence select="sum(/items/item/(value * quantity))"/>
    </xsl:template>
</xsl:stylesheet>

Когда это преобразование применяется к предоставленному XML-документу:

<items>
    <item>
        <value>1.0</value>
        <quantity>3</quantity>
    </item>
    <item>
        <value>2.5</value>
        <quantity>2</quantity>
    </item>
    <!-- ... -->
</items>

выражение XPath вычисляется и выводится результат этой оценки:

8

Пояснение:

В XPath 2.0 допустимо, чтобы шаг местоположения был

/(expression),

или даже

/someFunction(argumentList)

II. Решение XSLT 1.0:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/*">
  <xsl:call-template name="sumProducts">
    <xsl:with-param name="pNodes" select="item"/>
  </xsl:call-template>
 </xsl:template>

 <xsl:template name="sumProducts">
   <xsl:param name="pNodes" select="/.."/>
   <xsl:param name="pAccum" select="0"/>

   <xsl:choose>
    <xsl:when test="not($pNodes)">
     <xsl:value-of select="$pAccum"/>
    </xsl:when>
    <xsl:otherwise>
     <xsl:call-template name="sumProducts">
      <xsl:with-param name="pNodes" select="$pNodes[position() >1]"/>
      <xsl:with-param name="pAccum" select=
      "$pAccum + $pNodes[1]/value * $pNodes[1]/quantity"/>
     </xsl:call-template>
    </xsl:otherwise>
   </xsl:choose>
 </xsl:template>
</xsl:stylesheet>

когда это преобразование применяется к предоставленному XML-документу (выше), снова получается желаемый правильный результат:

8

Обратите внимание: такие проблемы легко решить с помощью библиотеки FXSL. . Шаблон для вызова transform-and-sum .

person Dimitre Novatchev    schedule 20.05.2012
comment
Как я прокомментировал другой ответ, это выглядит многообещающе для меня, но я не могу заставить его работать с PHP. Это проблема PHP, поддерживающего только XSLT 1.0/XPath 1.0, или я не правильно его адаптировал? Есть ли подобное решение для версии 1.0? - person hielsnoppe; 21.05.2012
comment
@hielsnoppe: AFAIK PHP использует libxml/libxslt, который реализует только XPath 1.0 / XSLT 1.0. Невозможно вычислить желаемое значение только с одним выражением XPath 1.0. Если вас интересует решение XSLT 1.0, пожалуйста, подтвердите, и я его предоставлю. - person Dimitre Novatchev; 21.05.2012
comment
Спасибо за разъяснения по этому поводу! Теперь я сам придумал решение, опубликованное как ответ. - person hielsnoppe; 21.05.2012

arrow_upward
1
arrow_downward

Попробуй это:

<xsl:stylesheet version="2.0"xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:template match="/">
        <xsl:sequence select="sum(/items/item/(value * quantity))"/>
    </xsl:template>
</xsl:stylesheet>
person web_bod    schedule 19.05.2012
comment
Выглядит многообещающе для меня, но не может заставить его работать с PHP XSLTProcessor. Это проблема PHP или я не правильно его адаптировал? - person hielsnoppe; 20.05.2012
comment
проблемы с записью по памяти - person web_bod; 20.05.2012

arrow_upward
1
arrow_downward

Основываясь на этом предложении https://stackoverflow.com/a/1334165/948404, я придумал решение, совместимое с XSLT. 1.0 и XPath 1.0, которые реализованы libxml/libxslt, используемые реализацией PHP XSLTProcessor (спасибо @Dimitre Novatchev за подтверждение).

<?xml version="1.0" encoding="UTF-8"?>
<xsl:transform version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:template match="/items">
        <xsl:call-template name="recursivesum">
            <xsl:with-param name="items" select="*" />
        </xsl:call-template>
    </xsl:template>

    <xsl:template name="recursivesum">
        <xsl:param name="items" />
        <xsl:param name="sum" select="0" />
        <xsl:variable name="head" select="$items[1]" />
        <xsl:variable name="tail" select="$items[position()>1]" />
        <xsl:variable name="thissum" select="$head/value * $head/quantity" />
        <xsl:choose>
            <xsl:when test="not($tail)">
                <xsl:value-of select="$sum+$thissum" />
            </xsl:when>
            <xsl:otherwise>
                <xsl:call-template name="recursivesum">
                    <xsl:with-param name="sum" select="$sum+$thissum" />
                    <xsl:with-param name="items" select="$tail" />
                </xsl:call-template>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

</xsl:transform>
person hielsnoppe    schedule 21.05.2012