Как передать массив Perl в виде скаляра в подпрограмму?

Проблема именно здесь:

my $missingtids = @_;

Вы вызываете массив @_ в скалярном контексте. Это означает, что вы назначаете $missingtids количество элементов в @_. Один из способов обойти это — передать ссылку на массив:

sub myqry {

    my $missingtids_ref = shift;
    my @missingtids=@$missingtids_ref;

    $sql = "select 
        i.tid i_tid, i.name i_name
        from 
        instrument i
        where i.tid in (" . join(",",@missingtids) . ")";

    print "$sql/n";
}

Для получения дополнительной информации см. perldoc perlref и perldoc perldata.

Здесь есть три проблемы. Первый использует прототип функции, просто оставьте его, см. Почему Perl 5 прототипы функций плохие?.

Второй — несоответствие типов в вызове функции и на стороне получателя самой функции. Либо используйте массивы оба раза, либо ссылки на массивы оба раза.

В-третьих, обработка данных как части SQL-запроса может открыть ворота для атаки с внедрением SQL. Это безопасно устраняется сборкой строки запроса с заполнителями для использования с DBI.

myqry(@arrMissingTids);
sub myqry {
    my @missingtids = @_;
    $sql = "select
        i.tid i_tid, i.name i_name
        from
        instrument i
        where i.tid in (" . join(',', ('?') x @missingtids) . ")";
    print "$sql\n";
    # $dbh->selectall_arrayref($sql, {}, @missingtids)
}

myqry(\@arrMissingTids);
sub myqry {
    my @missingtids = @{ shift() };
    $sql = "select
        i.tid i_tid, i.name i_name
        from
        instrument i
        where i.tid in (" . join(',', ('?') x @missingtids) . ")";
    print "$sql\n";
    # $dbh->selectall_arrayref($sql, {}, @missingtids)
}

Если кто-то еще не упомянул об этом, прототип здесь является проблемой:

sub myqry($) {

Учти это:

sub test1($) {
    print "$_\n" foreach @_;
}

sub test2 {
    print "$_\n" foreach @_;
}

my @args = ('a', 'b', 'c');

test1(@args);
test2(@args);      

и вывод:

3
a
b
c

К настоящему времени вы поняли, что массив в скалярном контексте — это просто количество элементов, например:

my $n = @args;

$n равно 3. Передавая массив в подпрограмму, которая сводит его к скаляру, вы получаете один аргумент — количество элементов в массиве. Затем вы делаете это:

my $missingtids = @_;

который всегда будет только один из-за ($) в подопределении (массив уже уменьшен до одного элемента). Следовательно, вы получаете 1.

$0,02: прототипы IMO на Perl — плохая идея ;)

Итак, вы хотите создать строку

... in (1,2,3,4)

Используйте join

myqry(join(',', @arrMissingTids))

Но это скорее наизнанку. Это было бы лучше:

sub myqry {
    my $missingtids = join(',', @_);

    return "select 
        i.tid i_tid, i.name i_name
        from 
        instrument i
        where i.tid in ($missingtids)
    ";
}

myqry(@arrMissingTids);

Спасибо за помощь. После того, как все было сказано и сделано, я в конечном итоге избавился от прототипа и использовал этот код, который отлично работал и был собран из всей справки выше:

myqry(@arrTids);

sub myqry {
   $missingtids = join(",",@_);

   .rest of code...
}

Непроверенный, но, вероятно, правильный:

myqry(\@arrMissingTids);

sub myqry($) {

    my $missingtids = shift; # or $_[0]

    $sql = "select 
        i.tid i_tid, i.name i_name
        from 
        instrument i
        where i.tid in (" . join(',', @{$missingtids}) . ")";

    print "$sql/n";
}

Конечно, вы можете передать сам массив вместо ссылки, но тогда вам нужно будет изменить прототип и переписать ссылки на массив. Но то, что выше, должно вас заинтересовать.